Если мы сталкиваемся с несколькими ошибками при использовании On Error Resume Next

Question

При использовании On Error Resume Next, он пропускает обнаруженную ошибку и переходит к следующей строке. Если мы используем err.Number и err.Description, оно показывает сообщение и номер, связанные с ошибкой. Мой вопрос: что, если он смотрит больше, чем на ошибку ... тогда как это будет отображаться?

On Error Resume Next 
    intDivideByZero 
    floatDivideByZero 
If err.Number <> 0 Then 
    msgbox "the error number is : " & err.Number 
    msgbox "the error description is : " & err.Description 
End If 
On error Resume 0 

Answer 1

Обработка ошибок VBScript довольно ограничена. Вам нужно будет поместить обработчик ошибок после каждой строки, где может произойти ошибка. Кроме того, объект Err не будет автоматически сброшен после ошибки, поэтому вам нужно сделать это самостоятельно. В противном случае объект будет по-прежнему указывать на ошибку после следующего утверждения, даже если там ничего не произошло.

On Error Resume Next 
intDivideByZero 
If Err Then 
    WScript.Echo "0x" & Hex(Err.Number) & ": " & Err.Description 
    Err.Clear 
End If 
floatDivideByZero 
If Err Then 
    WScript.Echo "0x" & Hex(Err.Number) & ": " & Err.Description 
    Err.Clear 
End If 
On Error Goto 0 

Вы можете упростить это немного обертывания обработчика в процедуре и вызов этой процедуры после каждого оператора:

Sub Trap 
    If Err Then 
     WScript.Echo "0x" & Hex(Err.Number) & ": " & Err.Description 
     Err.Clear 
    End If 
End Sub 

On Error Resume Next 
intDivideByZero : Trap 
floatDivideByZero : Trap 
On Error Goto 0