Перехват собственности классов домена Grails

Question

Я хотел бы перехватить вызовы на свойства классов домена для реализации контроля доступа.

Моя первая попытка была переопределить setProperty и getProperty. Делая это, я отключил все приятные функциональные возможности классов домена Grails, таких как

domainClass.properties = params 

и автоматическое преобразование типов данных.

Следующая попытка состояла в том, чтобы использовать DelegatingMetaClass, что позволило мне хотя бы распечатать несколько приятных сообщений журнала вокруг фактического вызова. Но я не мог понять, как получить доступ к фактическому объекту для оценки разрешений.

Последнее, groovy.lang.Interceptor, кажется, хороший выбор, так как я могу получить доступ к фактическому объекту. Но правильно ли это? Как я могу заставить все классы домена перехватываться?

Большое спасибо.

С уважением, Daniel

Answer 1

Вы можете переопределить GetProperty и SetProperty до тех пор, как вы ссылки на реальные версии. Добавьте код, как это Bootstrap для добавлений перехватчики для всех доменных классов:

class BootStrap { 

    def grailsApplication 

    def init = { servletContext -> 

     for (dc in grailsApplication.domainClasses) { 
     dc.class.metaClass.getProperty = { String name -> 
      // do stuff before access 
      def result 
      def metaProperty = delegate.class.metaClass.getMetaProperty(name) 
      if (metaProperty) { 
       result = metaProperty.getProperty(delegate) 
      } 
      else { 
       throw new MissingPropertyException(name, delegate.class) 
      } 
      // do stuff after access 
      result 
     } 

     dc.class.metaClass.setProperty = { String name, value -> 
      // do stuff before update 
      def metaProperty = delegate.class.metaClass.getMetaProperty(name) 
      if (metaProperty) { 
       metaProperty.setProperty(delegate, value) 
      } 
      else { 
       throw new MissingPropertyException(name, delegate.class) 
      } 
      // do stuff after update 
     } 
     } 
    } 

    def destroy = {} 
}