Windows, партия: задержка расширения в цикле

Question

Я хочу изменить несколько конкретных строк числа текстовых файлов, и я написал пакетный файл следующим образом:

@echo off 
set n=0 
set n1=10 
set n2=40 
cd.>output.txt 

for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set "var=%%i" 
setlocal enabledelayedexpansion 
set /a n=!n!+1 
echo.!n! 
set var=!var:*:=! 
rem if !n!=%n1% ... 
rem if !n!=%n2% ... 
(echo.!var!)>>output.txt 
endlocal 
) 
start output.txt 

Однако это не работает ожидается.
После некоторых тестов, я думаю, что расширение !n! обычно не задерживается. Это очень странно, потому что расширение !var! обычно задерживается.

Кстати, команды setlocal enabledelayedexpansion и endlocal помещаются в петлю for, потому что в противном случае особый характер ! будет заброшен.

Answer 1

Я полагаю, проблема в том, что вы видите, что n никогда не будет увеличиваться.

Но это не проблема задержки расширения, это эффект блока setlocal/endlocal внутри цикла.
Как упоминалось в panda-34, вы должны использовать расширенный синтаксис set/a и переместить оператор за пределами блока setlocal/endlocal.

@echo off 
set n=0 
set n1=10 
set n2=40 

(
    for /f "delims=" %%i in ('findstr /n .* test.txt') do (
    set "var=%%i" 
    set /a n+=1 
    setlocal enabledelayedexpansion 
    echo !n! 
    set var=!var:*:=! 
    rem if !n!=%n1% ... 
    rem if !n!=%n2% ... 
    (echo(!var!) 
    endlocal 
) 
) >output.txt 
start output.txt