Как разбить строку в T-SQL?

Question

У меня есть varchar @ a = 'a | b | c | d | e | f | g | h | i | j | k | l | m | n | o | p', которые имеют | разграниченные значения. Я хочу разбить эту переменную в массиве или таблице. У кого-нибудь есть представление об этом.

Answer 1

Используйте таблицу значных функции, как это,

CREATE FUNCTION Splitfn(@String varchar(8000), @Delimiter char(1))  
returns @temptable TABLE (items varchar(8000))  
as  
begin  
    declare @idx int  
    declare @slice varchar(8000)  

    select @idx = 1  
     if len(@String)<1 or @String is null return  

    while @idx!= 0  
    begin  
     set @idx = charindex(@Delimiter,@String)  
     if @idx!=0  
      set @slice = left(@String,@idx - 1)  
     else  
      set @slice = @String  

     if(len(@slice)>0) 
      insert into @temptable(Items) values(@slice)  

     set @String = right(@String,len(@String) - @idx)  
     if len(@String) = 0 break  
    end 
return  

end 

и получить переменную и использовать эту функцию, как это,

SELECT i.items FROM dbo.Splitfn(@a,'|') AS i 

Answer 2

В общем, это такой общий вопрос здесь

Я дам общий ответ: Arrays and Lists in SQL Server 2005 and Beyond от Erland Sommarskog

Я бы рекомендовал table of numbers, а не цикл, для общего использования.

Answer 3

Попробуйте это:

declare @a varchar(10) 
set @a = 'a|b|c|' 
while len(@a) > 1 
begin 
insert into #temp 
select substring(@a,1,patindex('%|%',@a)-1); 
set @a = substring(@a,patindex('%|%',@a)+1,len(@a)) 
end; 

Answer 4

Вот решение, основанное альтернатива XML. Похоже, что он имеет такую ​​же производительность, как и решение Splitfn().

Это преобразует varchar a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p в XML <a>a</a><a>b</a><a>c</a><a>d</a><a>e</a><a>f</a><a>g</a><a>h</a><a>i</a><a>j</a><a>k</a><a>l</a><a>m</a><a>n</a><a>o</a><a>p</a> и извлекает значение из каждого узла XML <a>.

declare @a  varchar(max); 
set @a = 'a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p'; 

declare @xml xml; 
set @xml  
    = '<a>'+replace(replace(replace(@a,'&','&amp;'),'<','&lt;'),'|','</a><a>')+'</a>'; 

SELECT x.n.value('.','VARCHAR(1)') AS singleValue 
FROM @xml.nodes('/a') AS x(n) 
;