слияния, чтобы установить значения по умолчанию, но потенциально дорогостоящие функции

Question

Идиоматического способу установить значения по умолчанию в Clojure является со слиянием:

;; `merge` can be used to support the setting of default values 
(merge {:foo "foo-default" :bar "bar-default"} 
     {:foo "custom-value"}) 
;;=> {:foo "custom-value" :bar "bar-default"} 

В действительности, однако, часто значения по умолчанию не являются простым, но постоянными вызовами функций. Очевидно, я хотел бы избежать вызова функции, если она не будет использоваться.

До сих пор я делаю что-то вроде:

(defn ensure-uuid [msg] 
    (if (:uuid msg) 
    msg 
    (assoc msg :uuid (random-uuid)))) 

и применить мои ensure-* функции, такие как (-> msg ensure-uuid ensure-xyz).

Что было бы более идиоматичным способом сделать это? Я имею в виду что-то вроде:

(merge-macro {:foo {:bar (expensive-func)} :xyz (other-fn)} my-map) 

(associf my-map 
    [:foo :bar] (expensive-func) 
    :xyz (other-fn)) 

Answer 1

Я просто адаптировали condp макросы и написал следующее:

(defmacro assoc-if-nil 
    "Takes a map as the first argument and a succession of key value pairs that 
    are used to set the key to value if the key of the map is nil. The value part 
    is only evaluated if the key is nil (thus different semantics to (merge)). 
    Example: 
    (assoc-if-nil {:a {:b :set}} 
    [:a :b] :non-def 
    [:a :c] :non-def 
    :d :non-def) 
    ;; =>{:a {:b :set, :c :non-def}, :d :non-def}" 
    [m & clauses] 
    (assert (even? (count clauses))) 
    (let [g (gensym) 
     get-fn (fn[kork] (if (vector? kork) `get-in `get)) 
     assoc-fn (fn[kork] (if (vector? kork) `assoc-in `assoc)) 
     pstep (fn [[kork v]] `(if-not (~(get-fn kork) ~g ~kork) 
           (~(assoc-fn kork) ~g ~kork ~v) 
           ~g))] 
    `(let [~g ~m ;; avoid double evaluation 
      ~@(interleave (repeat g) (map pstep (partition 2 clauses)))] 
     ~g))) 

который расширяется:

(macroexpand-1 ' 
(assoc-if-nil m 
       [:a :b] :nested 
       :d :just-key)) 

(clojure.core/let 
[G__15391  m 
    G__15391 
    (clojure.core/if-not 
    (clojure.core/get-in G__15391 [:a :b]) 
    (clojure.core/assoc-in G__15391 [:a :b] :nested) 
    G__15391) 
    G__15391 
    (clojure.core/if-not 
    (clojure.core/get G__15391 :d) 
    (clojure.core/assoc G__15391 :d :just-key) 
    G__15391)] 
G__15391) 

Answer 2

Вы можете использовать delay в сочетании с force.

Вы можете объединить ваши настройки по умолчанию, как

(merge {:foo "foo-default" :bar "bar-default" :uuid (delay (random-uuid))} 
     {:foo "custom-value" :uuid "abc"}) 

и значений доступа с использованием

(force (:foo ...)) 

или

(force (:uuid ...)) 

random-uuid будет называться только тогда, когда вы на самом деле нужно значение (и только в первый раз).

Вы можете обернуть звонок force в функцию get-value или что-то в этом роде.