Преобразовать строку "ABC" до $ хэша -> {а} -> {Ь} -> {C} в Perl

Question

Я динамические вложенные хэш-реф, как это:

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } }; 

Я хочу установить значение c на «что-то», позволяя пользователю вводить «abc something».

Теперь получение значение может быть сделано так:

my $keys = 'a.b.c'; 
my $v='something'; 
my $h = $hash; 
foreach my $k(split /\./, $keys) { 
    $h = $h->{$k}; 
} 
print $h; # "value" 

Но как бы я установить значение ключа c в $v так что

print Dumper $hash; 

будет отражать изменения ? $h не является ссылкой в ​​конце цикла foreach, поэтому изменение этого параметра не отразится на изменении в $hash. Любые подсказки, как решить узлы в моей голове?

Answer 1

Что-то вроде этого:

my $h = $hash; 
my @split_key = split /\./, $keys; 
my $last_key = pop @split_key; 
foreach my $k (@split_key) { 
    $h = $h->{$k}; 
} 
$h->{$last_key} = $v; 

Answer 2

use strictures; 
use Data::Diver qw(DiveVal); 

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } }, 
    'a.b.c', 
    'something', 
); 

DiveVal($hash, split /[.]/, $path) = $value; 
# { a => { b => { c => 'something' } } } 

Answer 3

выкатились последний ключ для wusses! ;)

sub dive :lvalue { 
    my $r = \shift; 
    $r = \(($$r)->{$_}) for @_; 
    return $$r; 
} 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

dive($data, split /\./, $key) = $val; 

Более мощная (и, таким образом, несколько сложнее в использовании) версия этой функции обеспечивается Data::Diver.

use Data::Diver qw(DiveVal); 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

DiveVal($data //= {}, map \$_, split /\./, $key) = $val; 

(использование daxim является немного прочь.)