Как создать набор узлов из значений

Question

Как создать набор узлов из значений ....

У меня есть n чисел 1,2,3 ....... n.

Я хочу, чтобы создать узел установить

<MYNMUMS> 
<MYNUM>1</MYNUM> 
<MYNUM>2</MYNUM> 
<MYNUM>3</MYNUM> 
<MYNUM>4</MYNUM> 
.... 
<MYNUM>N</MYNUM> 
</MYNMUMS> 

Answer 1

так легко, как:

XSLT 1.0 решение:

Это преобразование:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

    <xsl:template match="/"> 
    <MyNums> 
     <xsl:call-template name="generateNumNodes"> 
     <xsl:with-param name="pStart" select="1"/> 
     <xsl:with-param name="pEnd" select="10"/> 
     </xsl:call-template> 
    </MyNums> 
    </xsl:template> 

    <xsl:template name="generateNumNodes"> 
     <xsl:param name="pStart"/> 
     <xsl:param name="pEnd"/> 

     <xsl:if test="$pEnd >= $pStart"> 
     <xsl:variable name="vNumNodes" 
      select="$pStart -$pEnd+1"/> 

     <xsl:choose> 
      <xsl:when test="$vNumNodes = 1"> 
      <MyNum><xsl:value-of select="$pStart"/></MyNum> 
      </xsl:when> 
      <xsl:otherwise> 
      <xsl:variable name="vHalf" select= 
       "floor(($pStart+$pEnd) div 2)"/> 
      <xsl:call-template name="generateNumNodes"> 
       <xsl:with-param name="pStart" select="$pStart"/> 
       <xsl:with-param name="pEnd" select="$vHalf"/> 
      </xsl:call-template> 

      <xsl:call-template name="generateNumNodes"> 
       <xsl:with-param name="pStart" select="$vHalf+1"/> 
       <xsl:with-param name="pEnd" select="$pEnd"/> 
      </xsl:call-template> 
      </xsl:otherwise> 
     </xsl:choose> 
     </xsl:if> 
    </xsl:template> 
</xsl:stylesheet> 

при нанесении на любом документе XML (не используется), производит требуемый выход:

<MyNums> 
    <MyNum>1</MyNum> 
    <MyNum>2</MyNum> 
    <MyNum>3</MyNum> 
    <MyNum>4</MyNum> 
    <MyNum>5</MyNum> 
    <MyNum>6</MyNum> 
    <MyNum>7</MyNum> 
    <MyNum>8</MyNum> 
    <MyNum>9</MyNum> 
    <MyNum>10</MyNum> 
</MyNums> 

Обратите внимание следующее:

1. ШаблонgenerateNumNodesсебя рекурсивно вызовы.

2. Это рекурсия как раз (O(N)), и пространство (O(log2(N))) эффективным и практически не имеет переполнение стека - нет SO здесь!

3. выше особенность достигается за счет реализации рекурсии в СВЦ (DiVide and Conquer) стиле.

4. В отличие от tail-recursionон будет успешно выполнен на любом совместимом XSLT-процессоре.

5. Максимальная глубина рекурсии, необходимая для генерации 1000000 (один миллион номеров), составляет всего лишь 19.

решение XSLT 2.0:

Еще более элементарным, не рекурсии, только с помощью XPath 2.0 to оператор:

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 

    <xsl:template match="/"> 
     <MyNums> 
      <xsl:for-each select="1 to 10"> 
      <MyNums> 
       <xsl:sequence select="."/> 
      </MyNums> 
      </xsl:for-each> 
     </MyNums> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 2

XSLT это язык преобразований. Он обычно используется, когда у вас уже есть данные в форме XML-документа, который вы хотите преобразовать в другой документ (который может быть или не быть в формате XML).

Для того, чтобы начать с «сырых» данных и генерации представления XML, XSLT не подходит.

Предлагаю вам изучить различные языки, чтобы решить эту проблему.