Прямое индексирование по возвращаемому значению функции в fortran

Question

Есть ли возможность использовать индексирование непосредственно на возвращаемом значении функции? Что-то вроде этого:

readStr()(2:5) 

где readStr() это функция, которая возвращает строку символов. На многих других языках это вполне возможно, но как насчет Фортрана? Синтаксис в моем примере, конечно, не компилируется. Есть ли другой синтаксис для использования?

Answer 1

Нет, это невозможно в Фортране. Однако вы можете изменить свою функцию, чтобы взять дополнительный индексный массив, который определяет, какие элементы будут возвращены. Этот пример иллюстрирует эту возможность, используя интерфейс, позволяющий получить дополнительную спецификацию индексов (упрощенно благодаря комментарию от IanH):

module test_mod 
    implicit none 

    contains 

    function squareOpt(arr, idx) result(res) 
    real, intent(in)    :: arr(:) 
    integer, intent(in), optional :: idx(:) 
    real,allocatable    :: res(:) 
    real       :: res_(size(arr)) 
    integer      :: stat 

    ! Calculate as before 
    res_ = arr*arr 

    if (present(idx)) then 
     ! Take the sub-set  
     allocate(res(size(idx)), stat=stat) 
     if (stat /= 0) stop 'Cannot allocate memory!' 

     res = res_(idx) 
    else 
     ! Take the the whole array  
     allocate(res(size(arr)), stat=stat) 
     if (stat /= 0) stop 'Cannot allocate memory!' 

     res = res_ 
    endif 

    end function 
end module 

program test 
    use test_mod 
    implicit none 

    real :: arr(4) 
    integer :: idx(2) 

    arr = [ 1., 2., 3., 4. ] 
    idx = [ 2, 3] 

    print *, 'w/o indices',squareOpt(arr) 
    print *, 'w/ indices',squareOpt(arr, idx) 
end program 

Answer 2

No.

Но если это беспокоит вас, вы можете написать свои собственные пользовательские функции и операторы для достижения аналогичного результата без сохранения результата задания функции в отдельной переменной.