VBA цикл выхода в последнем истинном состоянии

Question

Я создаю макрос, который будет просматривать папку для всех файлов xls определенного типа отчета и перечислить их на листе с целым путем. Затем он оценивает их в порядке возрастания и находит самый последний файл, который открывается, а информация из него копируется в пустой файл как процесс, объединяющий самые последние данные из нескольких видов отчетов.

Проблема выхода из цикла после того, как последний файл был найден:

Dim i As Variant 
Dim myarray() As Integer 
Dim myarray2() As Variant 

i = 0 

For Each cell In Range("C1:C" & x) 
    If InStr(1, cell, "proof") Then 
     i = i + 1 
     Debug.Print i & " " & cell.value 
     ReDim myarray(i) 
     ReDim Preserve myarray2(cell) 
    End If 

    Do 
    Loop Until InStr(1, cell, "proof") 
Next cell 

Это пробный код - это выглядит для всех файлов, которые имеют "proof" в имени файла в указанной папке и затем печатает их в ближайшем окне. Динамический массив хранит каждое имя файла до тех пор, пока цикл не закончится, и цикл цикла Do Until должен остановить его при последнем условии, которое проверяет как истинное - это файл, который будет затем открыт и информация будет скопирована. Дело в том, что петля Do Until блокирует всю процедуру, так как первая итерация, которая является истиной, удовлетворит ее, и я не уверен, как ее завершить, где она должна ...

A Do-While цикл просто заканчивается тем, что едет на велосипеде, когда ставится в одно и то же место.

Answer 1

на самом деле не получите всю вашу цель. но вы могли бы попробовать это для начала

Option Explicit 

Sub main() 
    Dim i As Variant 
    Dim myarray() As String 
    Dim cell As Range 
    Dim firstAddress As String 
    Dim nFound As Long 

    With Range("C1", Cells(Rows.Count, "C").End(xlUp)) '<--| reference column "C" cells from row 1 down to last non empty one 
     nFound = WorksheetFunction.CountIf(.Cells, "*proof*") '<--| count occurrences of wanted substring 
     If nFound = 0 Then Exit Sub '<--| exit if no occurrences 
     ReDim myarray(1 To nFound) '<--| size your array to match occurrences 
     Set cell = .Find(what:="proof", after:=.Cells(.Rows.Count, 1), LookIn:=xlValues, lookat:=xlPart, searchdirection:=xlNext) '<--| find first occurrence 
     firstAddress = cell.Address '<--| store first occurrence address 
     Do 
      i = i + 1 '<-- update array index 
      myarray(i) = cell.Value '<--| update array current index content 
      Set cell = .FindNext(cell) '<--| search for next occurrence 
     Loop While cell.Address <> firstAddress '<--| exit if occurrence wrapped back to the first one 
    End With 
End Sub