Пакетный скрипт, перетаскивание и перетаскивание файла, расширение и перезагрузка файла

Question

У меня есть пакетный скрипт, который принимает> = 1 файл через drag & drop. Полные пути хранятся в массиве и затем передаются в другую программу в качестве входных данных. Имя файла + расширение хранится в другом массиве, который затем отображается пользователю.

Я пытаюсь проверить расширение файла, и если оно не является .bin, автоматически переименуйте файл, который я перетащил &, упал на .bin и перезагрузил его для добавления к двум массивам. Как я могу это сделать? Я пробовал некоторые команды if или %% ~ xi, но обычно он не обнаруживает, правильно ли это .bin или нет, и, конечно, путь не обновляется в массиве.

@echo off 
pushd %~dp0 
setlocal enabledelayedexpansion 
set /a Count = 0 

:START 
    set file="%~1" 
    if %file%=="" goto RUN 
    for %%i in (%file%) do set name=%%~nxi 
    set /a Count += 1 
    set [FilePath.!Count!]=%file% 
    set [FileName.!Count!]=%name% 
    shift 
goto START 

:RUN 
for /l %%i in (1, 1, %Count%) do (
    program.exe -command "![FilePath.%%i]!" 
    echo. 
    echo File Name: ![FileName.%%i]! 
    echo. 
    pause 
    cls 
    if exist file.log del file.log 
) 

Answer 1

Вы можете просто переименовать его во время совокупности массивов. Есть несколько других потенциальных проблем с вашим сценарием (например, pushd в некотируемом каталоге, delayedexpansion, где он не нужен, где он будет потенциально сбивать имена файлов, содержащих восклицательные знаки, и if %file%=="" должен содержать "%file%"). И действительно нет причин поддерживать массив имен файлов или цикл дважды. Ваш скрипт намного сложнее, чем нужно.

@echo off 
setlocal 

pushd "%~dp0" 

for %%I in (%*) do (
    if /I not "%%~xI"==".bin" move "%%~fI" "%%~dpnI.bin" >NUL 
    program.exe -command "%%~dpnI.bin" 
    echo; 
    echo File Name: "%%~nxI" 
    echo; 

    rem If you want to rename the file back the way it was after running 
    rem program.exe on it, uncomment the following line: 
    rem if /I not "%%~xI"==".bin" move "%%~dpnI.bin" "%%~fI" >NUL 

    pause 
    cls 
    if exist file.log del file.log 
)