Работа с рамками (Delphi)

Question

Я только начал использовать фреймы в Delphi.

Эти рамки находятся в FrameBar1, и оба они видны. Только для тестирования, сначала один содержит одну кнопку, а второй кадр содержит одно редактирование.

Я хочу изменить текст в Редакторе с помощью кнопки «Кнопка» (элементы управления на двух разных кадрах).

Как связаться между рамами?

Answer 1

Точно так же, как если бы элементы управления находились в одной и той же форме. Просто префикс управления Edit с объектом кадра, которому принадлежит это, например:

uses 
    Frame1Unit, Frame2Unit; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    Frame1 := TFrame1.Create(Self); 
    Frame1.Parent := ...; 
    ... 
    Frame2 := TFrame2.Create(Self); 
    Frame2.Parent := ...; 
    ... 
end; 

uses 
    Frame2Unit; 

procedure TFrame1.Button1Click(Sender: TObject); 
begin 
    Frame2.Edit1.Text := '...'; 
end; 

Лучше дизайн будет инкапсулировать логику так Frame1 и frame2 не знают друг о друге. Есть Frame1 выставить событие, которое он срабатывает при нажатии на кнопку, а затем родительская форма может назначить обработчик этого события и присвоить текст на frame2, например:

uses 
    Frame1Unit, Frame2Unit; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    Frame1 := TFrame1.Create(Self); 
    Frame1.Parent := ...; 
    Frame1.OnNewText := Frame1Text; 
    ... 
    Frame2 := TFrame2.Create(Self); 
    Frame2.Parent := ...; 
    ... 
end; 

procedure TForm1.Frame1Text(Sender: TObject; const NewText: string); 
begin 
    Frame2.EditText := NewText; 
end; 

type 
    TFrame1TextEvent = procedure(Sender: TObject; const NewText; string) of object; 

    TFrame1 = class(TFrame) 
    Button1: TButton; 
    procedure Button1Click(Sender: TObject); 
    public 
    OnNewText: TFrame1TextEvent; 
    end; 

procedure TFrame1.Button1Click(Sender: TObject); 
begin 
    if Assigned(OnNewText) then 
    OnNewText(Self, '...'); 
end; 

type 
    TFrame2 = class(TFrame) 
    Edit1: TEdit; 
    private 
    function GetEditText: string; 
    procedure SetEditText(const Value: string); 
    public 
    property EditText: string read GetEditText write SetEditText; 
    end; 

function TFrame2.GetEditText: string; 
begin 
    Result := Edit1.Text; 
end; 

procedure TFrame2.SetEditText(const Value: string); 
begin 
    Edit1.Text := Value; 
end;