Как переписать привязку ключа только на eshell?

Question

Я использую evil-mode на emacs, и недавно я начал использовать eshell. Мне очень нравится, как я могу покинуть режим вставки и переместить буфер eshell, чтобы скопировать содержимое или другие лакомства, но при повторном входе в режим ввода он делает это в курсоре текущего позиция, то, что я хотел бы, это то, что при входе в режим вставки автоматически переместите курсор на строку приглашения (последняя строка, конец строки).

Что я сделал:

(add-hook 'eshell-mode-hook 
     (lambda() 
     (define-key evil-normal-state-map (kbd "i") (lambda() (interactive) (evil-goto-line) (evil-append-line nil))))) 

Однако применяет это отображение во всех других буферов, я просто хочу, чтобы сделать его активным в буфере eshell.

Как определить привязку ключа, которая работает по-разному в eshell?

Answer 1

В настоящее время accepted answer удовлетворяет указанным требованиям, но имеет два основных ограничения:

1. Это вызывает только при входе в режим вставки с я. Переход к последней строке с я, А, , или любые пользовательские функции/сочетания клавиш потребует дополнительных сценариев.
2. Если point уже находится на последней строке (например, при редактировании текущей команды), нет способа войти в режим вставки в текущей позиции; i эффективно восстанавливается до A.

Первое ограничение можно устранить, сначала закрепив его на eshell-mode, а затем на evil-insert-state-entry.

Второе ограничение может быть решена путем установки положения point «s на основе первых на номер строки и второй на чтение только text-property:

1. Если point не уже на последней строке, то переместился на point-max (который всегда читается и записывается).
2. В противном случае, если текст в point доступен только для чтения, point перемещается в позицию в текущей строке, где изменяется текстовое свойство только для чтения.

Следующий код отменяет ограничения принятого ответа.

(defun move-point-to-writeable-last-line() 
    "Move the point to a non-read-only part of the last line. 
If point is not on the last line, move point to the maximum position 
in the buffer. Otherwise if the point is in read-only text, move the 
point forward out of the read-only sections." 
    (interactive) 
    (let* ((curline (line-number-at-pos)) 
     (endline (line-number-at-pos (point-max)))) 
    (if (= curline endline) 
     (if (not (eobp)) 
      (let (
        ;; Get text-properties at the current location 
        (plist (text-properties-at (point))) 
        ;; Record next change in text-properties 
        (next-change 
        (or (next-property-change (point) (current-buffer)) 
         (point-max)))) 
       ;; If current text is read-only, go to where that property changes 
       (if (plist-get plist 'read-only) 
        (goto-char next-change)))) 
     (goto-char (point-max))))) 

(defun move-point-on-insert-to-writeable-last-line() 
    "Only edit the current command in insert mode." 
    (add-hook 'evil-insert-state-entry-hook 
     'move-point-to-writeable-last-line 
     nil 
     t)) 

(add-hook 'eshell-mode-hook 
     'move-point-on-insert-to-writeable-last-line) 

Answer 2

Благодаря @lawlist указал мне в правильном направлении, решение так же просто, как:

;; Insert at prompt only on eshell 
(add-hook 'eshell-mode-hook 
     '(lambda() 
     (define-key evil-normal-state-local-map (kbd "i") (lambda() (interactive) (evil-goto-line) (evil-append-line nil))))) 

Спасибо!