CreateObject («Wscript.Shell») во всем мире не работает

Question

Я пытаюсь сделать функцию, которая выполняет команды, как это:

Set fso = CreateObject ("Scripting.FileSystemObject") 
Set stdout = fso.GetStandardStream (1) 
print runCommand("git --help") 

function runCommand(commandStr) 
    set objShell = CreateObject("Wscript.Shell") 
    Set objExec = objShell.Exec(commandStr) 

    Do Until objExec.Status 
     Wscript.Sleep 10 
    Loop 

    runCommand = objExec.StdOut.ReadAll() 
end function 

sub print(str) 
    stdout.WriteLine str 
end sub 

Это прекрасно работает, но я хочу использовать objShell на более высоком уровень, поэтому я решил сделать objShell глобальными:

set objShell = CreateObject("Wscript.Shell") 
Set fso = CreateObject ("Scripting.FileSystemObject") 
Set stdout = fso.GetStandardStream (1) 
print runCommand(objShell.CurrentDirectory) 
print runCommand("git --help") 

function runCommand(commandStr) 
    Set objExec = objShell.Exec(commandStr) 

    Do Until objExec.Status 
     Wscript.Sleep 10 
    Loop 

    runCommand = objExec.StdOut.ReadAll() 
end function 

sub print(str) 
    stdout.WriteLine str 
end sub 

Однако, теперь, когда я запускаю его я получаю сообщение об ошибке:

WshShell.Exec: Access is denied. 

И я t ссылается на строку set objShell = CreateObject("Wscript.Shell"). Если я попытаюсь сделать две разные переменные objShell и objShell2, я получаю ту же ошибку. Как это разрешить?

Answer 1

Мне удалось реплицировать вашу проблему локально. Я обнаружил, что область действия WScript.Shell не виновата.

Попробуйте это, и это, скорее всего, будет работать (обратите внимание на прокомментированную строку);

set objShell = CreateObject("Wscript.Shell") 
Set fso = CreateObject ("Scripting.FileSystemObject") 
Set stdout = fso.GetStandardStream (1) 
'print runCommand(objShell.CurrentDirectory) 
print runCommand("git --help") 

function runCommand(commandStr) 
    Set objExec = objShell.Exec(commandStr) 

    Do Until objExec.Status 
     Wscript.Sleep 10 
    Loop 

    runCommand = objExec.StdOut.ReadAll() 
end function 

sub print(str) 
    stdout.WriteLine str 
end sub 

Ошибка Access Denied по-видимому, связана с вызовом objShell.CurrentDirectory.

Проблема заключается в том, что вы пытаетесь передать текущий каталог objShell.Exec(), и он не знает, как его выполнить. (в конце концов это не приложение).

Вот пример в его простейшей форме;

CreateObject("Wscript.Shell").Exec("C:\") 

Выход:

WshShell.Exec: Access is denied. 

Если вы просто хотели, чтобы вывести текущий каталог, используя ваш скрипт, который вы, вероятно, хотел использовать

print objShell.CurrentDirectory 

вместо этого.