Использование нескольких классов для управления символом

Question

Я пытаюсь создать виртуальную игру домашнего животного/базового типа. Я должен использовать файлы независимых классов и вызывать их в главном файле игры. Я пытаюсь написать класс для управления моим персонажем, и я могу добавить его на сцену, но не могу, чтобы жизнь меня заставила его двигаться. Я только что потратил 4 часа на просмотр учебников, чтение книг и просто не вижу, чего не хватает. Может ли кто-нибудь предложить мне несколько советов, как заставить это работать? Вот мой код ...

Это мой основной класс ...

package { 

    import flash.display.MovieClip; 
    import MainCharacter; 
    import flash.events.KeyboardEvent; 

    public class Tamagotchi extends MovieClip { 

     public function Tamagotchi() { 
      var item:MainCharacter = new MainCharacter(); 
      addChild(item); 
      item.addEventListener(KeyboardEvent.KEY_DOWN, item.KeyPressListener); 
     } 

    } 
} 

Это классовый характер ...

package { 

    import flash.display.MovieClip; 
    import flash.events.KeyboardEvent; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 

    public class MainCharacter extends MovieClip { 

     var soph: MovieClip = new SophRun; 

     public function MainCharacter() { 
      addChild(soph); 
      soph.x = 200; 
      soph.y = 300;  
      soph.addEventListener(KeyboardEvent.KEY_DOWN, KeyPressListener); 
     } 

     public function KeyPressListener(e:KeyboardEvent):void { 
      if (e.keyCode == 65) 
      { 
       soph.x -= 2; 
      } 
      if (e.keyCode == 68) 
      { 
       soph.x += 2; 
      } 
      if (e.keyCode == 87) 
      { 
       soph.y -= 2; 
      } 
      if (e.keyCode == 83) 
      { 
       soph.y += 2; 
      } 
     } 

    } 
} 

Я переместил EventListener в нескольких местах и все еще не может заставить его работать. Я предполагаю, что у меня что-то не хватает, но не могу понять, что!

Answer 1

Вам необходимо добавить слушателя KeyboardEvent на сцену - в настоящее время он будет работать только в том случае, если ваш персонаж имеет текстовый фокус, чего у него никогда не будет.

Простая настройка, которая мне нравится, она имеет класс Input, который добавляет необходимые прослушиватели событий, и затем вы можете использовать, чтобы проверить, нажаты ли клавиши. Что-то вроде:

public class Input 
{ 
    // handy constants for common keys 
    public static const A:int = 65; 
    public static const B:int = 66; 
    ... 
    public static const LEFT:int = 37; 
    public static const UP:int = 38; 
    public static const RIGHT:int = 39; 
    public static const DOWN:int = 40; 

    private var m_keysPressed:Vector.<Boolean> = null; // the keys currently pressed 

    public function Input(stage:Stage) 
    { 
     // we create our vector for the max number of keys that we're going to support (standard keyboard) 
     this.m_keysPressed = new Vector.<Boolean>(225, true); 

     // add our listeners 
     stage.addEventListener(KeyboardEvent.KEY_DOWN, this._onKeyDown); 
     stage.addEventListener(KeyboardEvent.KEY_UP, this._onKeyUp); 
    } 

    public function isKeyPressed(key:int):Boolean 
    { 
     if(key < 0 || key >= this.m_keysPressed.length) 
      return false; 
     return this.m_keysPressed[key]; 
    } 

    private function _onKeyDown(e:KeyboardEvent):void 

     this.m_keysPressed[e.keyCode] = true; 
    } 

    private function _onKeyUp(e:KeyboardEvent):void 
    { 
     this.m_keysPressed[e.keyCode] = false; 
    } 
} 

Таким образом, весь ваш код ввода является центральным. Вы можете назвать это с помощью:

if(myInput.isKeyPressed(Input.UP)) 
    // move up 

Польза:

• Ваш код центральный - легко изменить
• Легко отключить или включить (функциональность паузы)
• Вы можете добавить простой обратные вызовы (Dictionary с int ключ и Function значение)
• Вы можете добавить такие методы, как justPressed(key) или justReleased(key) легко
• Вы не получает проблему повторяющихся ключей (при удержании клавиши, Flash будет повторять KEY_DOWN события)

Вам может понадобиться добавить ограничивающую проверку для функций _onKeyDown() и _onKeyUp(), если это вы планируете использовать это на мобильных устройствах, так как клавиши Android Home и Back имеют тупо высокие значения keyCode.

Примечание: если она по-прежнему не работает, убедитесь, что вы дали фокус стадии (т.е. нажал на нее), и вы не в (stage.focus = null)