Экспорт в CSV

Question

Я хочу экспортировать в CSV, а не «Сохранить как», поэтому создайте кнопку, которая будет включена макросом. При нажатии на нее должен быть создан CSV-файл первого листа в указанном каталоге, а также указанное имя. И мой первоначальный рабочий лист должен быть сохранен и не сохранен как.

Answer 1

Если у вас нет запятых, встроенные в клетки, это может быть достаточно:

Sub CSV_Maker() 
    Dim r As Range 
    Dim sOut As String, k As Long, M As Long 
    Dim N As Long, nFirstRow As Long, nLastRow As Long 

    Sheets(1).Select 

    ActiveSheet.UsedRange 
    Set r = ActiveSheet.UsedRange 
    nLastRow = r.Rows.Count + r.Row - 1 
    nFirstRow = r.Row 
    Dim separator As String 
    separator = "," 

    MyFilePath = "C:\TestFolder\" 
    MyFileName = "whatever" 
    Set fs = CreateObject("Scripting.FileSystemObject") 
    Set a = fs.CreateTextFile(MyFilePath & MyFileName & ".csv", True) 

    For N = nFirstRow To nLastRow 
     k = Application.WorksheetFunction.CountA(Cells(N, 1).EntireRow) 
     sOut = "" 
     If k = 0 Then 
      sOut = vbCrLf 
     Else 
      M = Cells(N, Columns.Count).End(xlToLeft).Column 
      For mm = 1 To M 
       sOut = sOut & Cells(N, mm).Value & separator 
      Next mm 
      sOut = Left(sOut, Len(sOut) - 1) 
     End If 
     a.writeline (sOut) 
    Next 

    a.Close 
End Sub 

Answer 2

Если точка сохранить оригинальную книгу нетронутыми, то почему бы не получить творческий. Мы можем скопировать лист в другую книгу и сохранить в формате .csv

Option Explicit 

Sub ExportOneSheet() 

    Const strFILE_NAME As String = "C:\Users\Tom\Desktop\tes.csv" 

    Dim shToExport As Worksheet 

    ' Set the sheet to copy 
    Set shToExport = ActiveWorkbook.Sheets("Sheet1") 

    ' Make a copy of the sheet, when called without argument 
    ' it will create a new workbook 
    shToExport.Copy 
    Set shToExport = ActiveWorkbook.Sheets("Sheet1") 

    ' If the file exists the delete it. This will esure that 
    ' there is no previous file so the replace file thing will not show 
    If Not Dir$(strFILE_NAME, vbNormal) = vbNullString Then 
     Kill strFILE_NAME 
    End If 

    ' Use Save As and your original workbook stays untouched. 
    shToExport.SaveAs strFILE_NAME, XlFileFormat.xlCSV 
    shToExport.Parent.Close True 

End Sub 

Я надеюсь, что это помогает :)