VBA - генерация уникальных номеров в коде

Question

Есть ли способ, которым я могу сгенерировать уникальный номер в коде? У меня была идея использовать системное время для этого, но в итоге не смогла его реализовать.

Answer 1

Вы можете нам теперь() форматировать вывод на число.

Sub unique() 

Dim t As Date 
t = Now() 
Range("A1").NumberFormat = "@" 
Range("A1") = CStr(Format(t, "yyyymmddhhMMss")) 
End Sub 

Это было бы уникально.

Как @Vasily указал, не форматируя ячейку как строку и помещая ее в качестве укуса, значение усекается до научной нотации.

Answer 2

специально для таких случаев был изобретен GUID (глобальный уникальный идентификатор). Это может быть немного слишком большим ... но только что вы видели:

Option Explicit 

Public Type TYP_GUID 
    bytes(15) As Byte 
End Type 

Public Declare Function CoCreateGuid Lib "OLE32.dll" _ 
         (guid As TYP_GUID) As Long 

Public Function newGUID() As TYP_GUID 
    Dim uGUID As TYP_GUID 
    CoCreateGuid uGUID 
    newGUID = uGUID 
End Function 

всякий раз, когда вы звоните newGUID() вы станете значением, которое должно быть действительно уникальным в мире. Вы можете попробовать и назвать его так часто, как хотите ... вы никогда не получите такое же значение во второй раз.

это также можно преобразовать такие GUID, чтобы строка:

Option Explicit 

Public Type TYP_GUID 
    bytes(15) As Byte 
End Type 

Public Declare Function CoCreateGuid Lib "OLE32.dll" _ 
         (guid As TYP_GUID) As Long 

Public Declare Function StringFromGUID2 Lib "OLE32.dll" _ 
         (guid As TYP_GUID, _ 
         ByVal lpszString As String, _ 
         ByVal iMax As Long) As Long 

Public Function newGUID() As TYP_GUID 
    Dim uGUID As TYP_GUID 
    CoCreateGuid uGUID 
    newGUID = uGUID 
End Function 

Public Function newGUID_String() As String 
    Dim sBuffer As String 
    Dim lResult As Long 

    sBuffer = VBA.Space(78) 
    lResult = StringFromGUID2(newGUID, sBuffer, Len(sBuffer)) 
    newGUID_String = Left$(StrConv(sBuffer, vbFromUnicode), lResult - 1) 
End Function