Applescript получить список запущенных приложений?

Question

Applescript newbie question again :) Я пытаюсь создать небольшой applescript, который позволит мне выбрать несколько элементов из списка запущенных приложений, а затем выйти из выбранных приложений. Что-то вроде этого работает, но вместо того, чтобы нажимать на каждый диалог, было бы намного проще выбрать из списка.

tell application "System Events" 
repeat with p in every process 
    if background only of p is false then 
     display dialog "Would you like to quit " & name of p & "?" as string 
    end if 
end repeat 
end tell 

Любая помощь будет принята с благодарностью!

Спасибо!

Answer 1

Попробуйте это:

tell application "System Events" 
    set listOfProcesses to (name of every process where background only is false) 
    tell me to set selectedProcesses to choose from list listOfProcesses with multiple selections allowed 
end tell 
--The variable `selectedProcesses` will contain the list of selected items. 
repeat with processName in selectedProcesses 
    do shell script "Killall " & quoted form of processName 
end repeat 

Answer 2

Вы можете попробовать это

tell application "System Events" 
     set AppName to name of every process whose background only is false 
     choose from list AppName OK button name "Ok" cancel button name "Cancel" 
    end 

Answer 3

tell application "System Events" 
    set processList to get the name of every process whose background only is false 
    set processNameList to choose from list processList with prompt "Select process to quit" with multiple selections allowed 
    if the result is not false then 
     repeat with processName in processNameList 
      do shell script "Killall " & quoted form of processName 
     end repeat 
    end if 
end tell 

Answer 4

& (name of every process whose (name is "AppName") могут быть добавлены к Michele Percich's и Parag Bafna's решений включают в себя конкретные строки меню приложений по имени ,

tell application processName to quit может использоваться вместо do shell script "Killall " & quoted form of processName.

tell application "System Events" 
    set processList to ¬ 
     (name of every process where background only is false) & ¬ 
     (name of every process whose ¬ 
      (name is "AppName") or ¬ 
      (name is "AnotherAppName")) 
    tell me to set selectedProcesses to choose from list processList with prompt "Select process(es) to quit:" with multiple selections allowed 
end tell 
if the result is not false then 
    repeat with processName in selectedProcesses 
     tell application processName to quit 
    end repeat 
end if 

Answer 5

вы можете использовать этот скрипт, который намного проще

tell application "Finder" 
    get the name of every process whose visible is true 
end tell