Toggling упорной подсказки

Question

Я хочу создать несколько подсказок, которые самосвалы информации о окне на основе MouseGetPos:

1. ^Space = Контекстный будет включаться и выключаться, и следую за мышью
2. ^+Space = всплывающую подсказку появляется временно, а затем исчезает
3. ^!+Space = Контекстное переключается и появляется в нижнем левом углу экрана

Однако всплывающая подсказка не исчезает для 1 & 2. 3 Дает ошибку «действие не определено».

Вот мой текущий код:

#CommentFlag // 
Toggle := False 

^Space:: // Toggle the tooltip and follow the mouse 

    If (Toggle = False) { 

     Toggle := True 
     #Persistent 
     SetTimer, WatchCursor // If I have just 'WatchCursor', without '#Persistent' and 'SetTimer', I get an "Action not defined" error 

    } Else If (Toggle = True) { 

     Toggle := False 
     ToolTip 

    } 
Return 

^+Space:: // Tooltip follows mouse, but disappears after 1 second 

    #Persistent 
    SetTimer, WatchCursor, 1000 

Return 

^!+Space:: // Tooltip appears at 1511, 3010 

    #Persistent 
    WatchCursor2 // Error: This line does not contain a recognized action 

Return 

WatchCursor: 
MouseGetPos, x, y, id, control 
WinGetTitle, title, ahk_id %id% 
WinGetClass, class, ahk_id %id% 
ToolTip, -- Window Info --`n`tahk_id:`t%id%`n`tahk_class:`t%class%`n`tTitle:`t%title%`n`tControl:`t%control%`n`n-- Mouse Pos --`n`tX:`t%x%`n`tY:`t%y% 

WatchCursor2: 
MouseGetPos, x, y, id, control 
WinGetTitle, title, ahk_id %id% 
WinGetClass, class, ahk_id %id% 
ToolTip, -- Window Info --`n`tahk_id:`t%id%`n`tahk_class:`t%class%`n`tTitle:`t%title%`n`tControl:`t%control%`n`n-- Mouse Pos --`n`tX:`t%x%`n`tY:`t%y%,1511,3010 

Answer 1

AutoHotkey сценарий ниже, должен дать вам точную функциональность вам требуется. Я внесла некоторые поправки и комментарии, , которые должны объяснить возникшие проблемы.

#CommentFlag // 
// #Persistent is not necessary for this script, 
// the presence of at least one hotkey, 
// is one way to make a script persistent 

Toggle := False 

// #p::Pause 

^Space:: // Toggle the tooltip and follow the mouse 

    If (Toggle = False) { 

     Toggle := True 
     vTickCount1 := A_TickCount 
     SetTimer, WatchCursor 

    } Else If (Toggle = True) { 

     Toggle := False 
     SetTimer, WatchCursor, Off 
     // ToolTip 

    } 

Return 

^+Space:: // Tooltip follows mouse, but disappears after 1 second 

    SetTimer, WatchCursor1, -1000 // negative to run once and then stop 
    MouseGetPos, x, y, id, control 
    WinGetTitle, title, ahk_id %id% 
    WinGetClass, class, ahk_id %id% 
    ToolTip, -- Window Info --`n`tahk_id:`t%id%`n`tahk_class:`t%class%`n`tTitle:`t%title%`n`tControl:`t%control%`n`n-- Mouse Pos --`n`tX:`t%x%`n`tY:`t%y% 

Return 

^!+Space:: // Tooltip appears at 1511, 3010 

Gosub WatchCursor2 

Return 

WatchCursor1: 
ToolTip 
Return 

WatchCursor: 
MouseGetPos, x, y, id, control 
WinGetTitle, title, ahk_id %id% 
WinGetClass, class, ahk_id %id% 
ToolTip, -- Window Info --`n`tahk_id:`t%id%`n`tahk_class:`t%class%`n`tTitle:`t%title%`n`tControl:`t%control%`n`n-- Mouse Pos --`n`tX:`t%x%`n`tY:`t%y% 

// if (A_TickCount - vTickCount1 > 5000) 
// { 
// SetTimer, WatchCursor, Off 
// ToolTip 
// } 
Return // without this line the lines below in WatchCursor2 will also be triggered 

WatchCursor2: 
MouseGetPos, x, y, id, control 
WinGetTitle, title, ahk_id %id% 
WinGetClass, class, ahk_id %id% 
ToolTip, -- Window Info --`n`tahk_id:`t%id%`n`tahk_class:`t%class%`n`tTitle:`t%title%`n`tControl:`t%control%`n`n-- Mouse Pos --`n`tX:`t%x%`n`tY:`t%y%,1511,3010 
Return 

Примечание: Это был довольно приятный сценарий и приятный для работы.
Примечание: AccViewer AutoHotkey - очень полезный скрипт для извлечения информации о окнах и элементах управления, iWB2 Learner также полезен для получения информации о веб-элементах в Internet Explorer.