Delphi скрыть форму, не скрыть значок приложения на панели задач

Question

я использую следующий код:

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    Form1.visible := false; 
    Form2.show; 
end; 

Да, form1 получил скрытое и Form2 шоу вверх. Но почему значок приложения на панели задач также скрыт ...

Я использую следующие коды и по-прежнему не могу показать значок на панели задач, а скрыть форму1.

 visible := false; 
{ 
     enable := false; 
     Application.MainFormOnTaskbar := True; 
     ShowWindow(Application.Handle, SW_SHOW); 
     SetWindowLong(Application.Handle, GWL_EXSTYLE, GetWindowLong(Application.Handle, GWL_EXSTYLE) or WS_EX_TOOLWINDOW); 
} 

Как сохранить значок приложения на панели задач, пока я хочу скрыть форму?

Я хочу сделать это в файлах устройств, а не в файле DPR.

файлы, которые я хочу сделать держать систему панели задач находятся: http://sidhiciang.com/myfiles/ShowHideForms.rar

Unit1.pas 
    If Form1.btShowForm2Click() , then 
    Hide Form1 and Show Form2 (actHideForm1execute(self)). 
    If Form1.btCloseForm1Click(), then 
    Close the application 

Unit2.pas 
    If Form2.btShowForm3Click(), then 
    Hide Form2 and Show Form3 (actHideForm2execute(self)). 
    If Form2.btCloseForm2Click(), then 
    Show the Form1 and Form2.close (actShowForm1execute(self)) 

Unit3.pas 
    If btCloseFrom3Click(), then 
    Show Form2 and Close Form3 

Во всех Unit1/unit2/Unit3, Держите значок приложения на панели задач доступны. Потому что, если я использую .visible: = false, панель задач системы также становится скрытой.

PS: Я использую Delphi 2010 и работает под Windows XP и 7 Enviorment.

Answer 1

Хорошо, теперь, когда ясно, что вы хотите, первые несколько вещей:

• Первая форма создается автоматически является MainForm,
• Приложение не может без MainForm; когда MainForm закрывается, приложение закрывается, любые другие формы показаны,
• Вы можете скрыть MainForm,
• По умолчанию (в старых версиях Delphi в любом случае) окно приложения отображается на панели задач (Application.MainFormOnTaskbar = False). Пока приложение активно, и пока отображается хотя бы одна форма, этот значок/окно отображается на панели задач.
• Когда Application.MainFormOnTaskbar = True, то значок/окно MainForm отображается на панели задач. Когда MainForm скрывается, значок исчезает. Отображение другой формы не приводит к другому значку/окну панели задач, поэтому в этом случае нет значка.

Итак, ясно, что вам необходимо установить Application.MainFormOnTaskbar := False в файле проекта.

Кроме того, следующая комбинация методов, кажется, работает, как вы хотите:

Unit1/Form1/MainForm:

procedure TForm1.CloseButtonClick(Sender: TObject); 
begin 
    Close; 
end; 

procedure TForm1.OpenForm2ButtonClick(Sender: TObject); 
begin 
    TForm2.Create(Self).Show; 
    Hide; 
end; 

Unit2/Form2:

procedure TForm2.CloseButtonClick(Sender: TObject); 
begin 
    Close; 
end; 

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction); 
begin 
    TForm(Owner).Show; 
    Action := caFree; 
end; 

procedure TForm2.OpenForm3ButtonClick(Sender: TObject); 
begin 
    TForm3.Create(Self).Show; 
    Hide; 
end; 

Единица3/Форма 3:

procedure TForm3.CloseButtonClick(Sender: TObject); 
begin 
    Close; 
end; 

procedure TForm3.FormClose(Sender: TObject; var Action: TCloseAction); 
begin 
    TForm(Owner).Show; 
    Action := caFree; 
end; 

Обратите внимание, что заголовок кнопки на панели задач остается неизменным во время этих изменений. Если вы хотите синхронизировать это с заголовком отображаемой формы, установите Application.Title.

Answer 2

Вы можете переключаться между ручками, показанными на панели задач.
Показать приложение для скрытия и формы при показе.

procedure TForm1.HideIt; 
begin 
    Visible := false; 
    Application.MainFormOnTaskbar := false; 
    ShowWindow(Application.Handle, SW_SHOW); 
end; 

procedure TForm1.ShowIt; 
begin 
    Visible := true; 
    Application.MainFormOnTaskbar := true; 
    ShowWindow(Application.Handle, SW_Hide); 
end; 

// overrride CreateParams: procedure CreateParams(var Params: TCreateParams); override; 
procedure TForm1.CreateParams(var Params: TCreateParams); 
begin 
    inherited; 
    Params.ExStyle := Params.ExStyle or WS_EX_APPWINDOW; 
end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    Application.MainFormOnTaskbar := true; 
end; 

Answer 3

Предполагая Form1 будучи основной формой и Form1.Hide делать все, что вы хотите, за исключением того, что кнопка на панели задач должна оставаться видимой, то, что вы действительно хотите сделать, это свести к минимуму применение:

Application.Minimize; 

---

В противном случае вы, вероятно, ищете Hide the Main Form.