XSLT: разбор текста с тегом

Question

У меня есть XML, как это:

<main> 
text1 <tag>2</tag> text3 
</main> 

должны быть преобразованы с помощью XSLT в:

<newMain> 
text1 <tag2>2</tag2>text3 
</newMain> 

, но я не знаю, как получить его. Вы можете мне помочь?

Благодаря

Rand

Answer 1

<xsl:template match="main | tag"> 
    <xsl:element name="{name()}2"> 
    <xs:apply-templates/> 
    </xsl:element> 
</xsl:template> 

должно быть достаточно, если вы просто хотите добавить "2" в названии элементов. Если вы хотите взять номер для элемента «тег» из содержимого, то, например,

<xsl:template match="main"> 
     <xsl:element name="{name()}2"> 
     <xs:apply-templates/> 
     </xsl:element> 
    </xsl:template> 

<xsl:template match="tag"> 
    <xsl:element name="{name()}{.}"> 
    <xsl:apply-templates/> 
    </xsl:element> 
</xsl:template> 

Answer 2

Это преобразование:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:my="my:my"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<my:reps> 
    <rep old="main" new="newMain"/> 
    <rep old="tag" new="tag2"/> 
</my:reps> 

<xsl:variable name="vReps" select="document('')/*/my:reps/*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match= 
    "*[name() = document('')/*/my:reps/*/@old]"> 

<xsl:element name="{$vReps[@old = name(current())]/@new}"> 
    <xsl:apply-templates select="node()|@*"/> 
</xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

при нанесении на поставленном XML документа:

<main> 
text1 <tag>2</tag> text3 
</main> 

производит разыскиваемого, правильный результат:

<newMain> 
text1 <tag2>2</tag2> text3 
</newMain>