Не удается завершить потоки

Question

Я использую потоки в своем проекте. И я хочу убить и немедленно прекратить нить.

образец:

type 
     test = class(TThread) 
     private 
     { Private declarations } 
     protected 
     procedure Execute; override; 
     end; 

    var 
    Form1: TForm1; 
    a:tthread; 

    implementation 

    {$R *.dfm} 

    procedure test.Execute; 
    begin 

     Synchronize(procedure begin  
      form1.ProgressBar1.position := 0; 
      sleep(5000); 
      form1.ProgressBar1.position := 100;  
     end 
    ); 

    end; 

    procedure TForm1.btn_startClick(Sender: TObject); 
    begin 
    a:=test.Create(false); 
    end; 

    procedure TForm1.btn_stopClick(Sender: TObject); 
    begin 
    terminatethread(a.ThreadID,1); //Force Terminate 
    end; 

Но когда я нажимаю на btn_stop (после нажатия на btn_start), нить не остановится. Итак, как можно немедленно остановить эту тему?

BTW a.terminate; не работал.

Спасибо.

Answer 1

Это полное злоупотребление рабочей нитью. Вы делегируете всю работу потока в основной поток, делая рабочий поток бесполезным. Вместо этого вы могли бы использовать простой таймер.

Правильное использование рабочего потока будет выглядеть следующим образом, вместо:

type 
    test = class(TThread) 
    private 
    { Private declarations } 
    protected 
    procedure Execute; override; 
    end; 

var 
    Form1: TForm1; 
    a: test = nil; 

implementation 

{$R *.dfm} 

procedure test.Execute; 
var 
    I: integer 
begin 
    Synchronize(
    procedure begin  
     form1.ProgressBar1.Position := 0; 
    end 
); 

    for I := 1 to 5 do 
    begin 
    if Terminated then Exit; 
    Sleep(1000); 
    if Terminated then Exit; 
    Synchronize(
     procedure begin 
     Form1.ProgressBar1.Position := I * 20; 
     end 
    ); 
    end; 

    Synchronize(
    procedure begin 
     form1.ProgressBar1.Position := 100;  
    end 
); 
end; 

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction); 
begin 
    btn_stopClick(nil); 
end; 

procedure TForm1.btn_startClick(Sender: TObject); 
begin 
    if a = nil then 
    a := test.Create(False); 
end; 

procedure TForm1.btn_stopClick(Sender: TObject); 
begin 
    if a = nil then Exit; 
    a.Terminate; 
    a.WaitFor; 
    FreeAndNil(a); 
end; 

Answer 2

Проблема заключается поток ожидает от использования Sleep. Этот метод будет поддерживать поток в течение указанного времени независимо от того, что происходит вокруг него. Чтобы иметь возможность «сломать сон», вы должны использовать событие. Код должен быть изменен следующим образом:

procedure test.Execute; 
begin 
    Synchronize(procedure begin  
     form1.ProgressBar1.position := 0; 
    end); 
    Event.WaitFor(5000); 
    if not IsTerminated then 
    Synchronize(procedure begin  
     form1.ProgressBar1.position := 100;  
    end); 
end; 

событие должно создаваться и уничтожаться, как это:

constructor test.Create(aCreateSuspended: Boolean); 
begin 
    inherited; 
    Event := TSimpleEvent.Create; 
end; 

destructor test.Destroy; 
begin 
    FreeAndNil(Event); 
    inherited; 
end; 

Для того, чтобы остановить поток, код:

procedure TForm1.btn_stopClick(Sender: TObject); 
begin 
    a.Terminate; 
end; 

Но просто вызов Terminate не будет сигнализировать о событии, поэтому мы должны переопределить Terminate:

procedure test.Terminate; 
begin 
    inherited; 
    Event.SetEvent; 
end; 

Вызов SetEvent будет сигнализировать о событии, поэтому он пробудит поток вверх. Выполнение продолжается в следующей строке, которая проверяет завершение потока и решает выполнить вторую часть кода или нет.