Переместить файлы в другую папку, включая дату создания в filename

Question

Я могу перемещать файлы из одной папки в другую, но проблема в том, что я хочу, чтобы новый созданный файл в новой папке был создан как дата создания и имя файла.

Например

/scripts/a.log 

переехал в

/log/8june2012a.log 

Answer 1

cp filename "`date +%Y%m%d`filename" 

Это копирует имя файла в 20120608filename. Для примера это то, что вы хотите:

cp filename "`date +%d%b%Y`filename" 

Это копии файла в 08jun2012filename. Если вы хотите переместить файл вместо копирования использовать mv вместо cp:

mv filename "`date +%d%b%Y`filename" 

Answer 2

use File::Copy; 
move("a.log",$DIRECTORY.get_timestamp().".log"); 

Ваша функция get_timestamp должна генерировать дату.

Answer 3

Я написал демо для вас,

#!/bin/bash 

DATE=`date +"%e%B%Y" | tr -d ' ' | tr A-Z a-z` 


for FILENAME in *.log 
do 
     cp "${FILENAME}" "/log/${DATE}${FILENAME}" 
done 

вы можете запустить в папке «сценарии».

Answer 4

Используя пару модулей CPAN это можно сделать простым. File::Copy был основным модулем с Perl версии 5.0, но Date::Format и Path::Class потребуется установка, если у вас уже есть их.

Я принял ваше требование буквально, и это решение префикс исходного файла с датой создания с использованием %e%B%Y в качестве формата, при этом верхний регистр переводится в нижний регистр и пробелы. Однако это не очень читаемый и листинг каталога не будет автоматически сортировать в хронологическом порядке, поэтому я рекомендую использовать %Y-%m-%d- вместо заменив строку, содержащую призыв к strftime с

my $date = lc strftime('%Y-%m-%d-', @date) 

В настоящее время код просто выводит список файлов, которые он собирается переместить, и их назначения. Чтобы на самом деле сделать ход, вы должны раскомментировать звонок до move.

use strict; 
use warnings; 

use Path::Class 'dir'; 
use Date::Format 'strftime'; 
use File::Copy 'move'; 

my $source = dir '/scripts/'; 
my $dest = dir '/log/'; 

for my $file (grep { not $_->is_dir } $source->children) { 

    my @date = localtime $file->stat->ctime; 
    (my $date = lc strftime('%e%B%Y', @date)) =~ tr/\x20//d; 

    my $newfile = $dest->file($date.$file->basename); 

    print "move $file -> $newfile\n"; 
    # move $file, $newfile; 
} 

Answer 5

Решения на Perl.

#!/usr/bin/perl 

use strict; 
use warnings; 
use File::Copy 'move'; 
use Time::Piece 'localtime'; 

my $indir = '/scripts'; 
my $outdir = '/log'; 

# get all of the files in the scripts dir 
chdir $indir; 
my @files = grep -f, glob '*'; 

foreach my $infile (@files) { 
    # get the date that the file was created 
    my $file_created_date = localtime((stat $infile)[9]); 
    my $outfile = $file_created_date->strftime('%d%B%Y').$infile; 
    move $infile, "$outdir/$outfile"; 
} 

Как и в сторону, я бы форматировать дату как %Y%m%d (ггггммдд), поскольку это дает последовательный формат и позволяет сортировать по дате более легко.

Answer 6

Другое решение.

use strict ; 
use File::stat ; 
use POSIX qw(strftime); 

my $File = 'mv.pl'; 
my $NewFile=strftime("%d%B%Y",localtime(stat($File)->ctime)) . $File ; 

rename $File, $NewFile;