Бесконечный пакетный скрипт останавливается через некоторое время

Question

Я создал файл сценария партии, чтобы обнаружить возникновение определенного события. Тогда я побежал, что пакетный файл в качестве фонового процесса, используя следующий код, сохраняются в файле .vbs:

CreateObject("Wscript.Shell").Run """" & WScript.Arguments(0) & """", 0, False 

Я не знаю, почему через 1 - 2 часа процесс этой работы исчезнет, ​​или я не» я знаю, почему эта работа не работает непрерывно, без каких-либо перерывов, как ее планировали и планировали делать.

Может ли кто-нибудь сказать мне, почему? И как решить эту проблему? Я имею в виду, как заставить мой скрытый командный файл работать в течение неограниченного периода времени?

Это пакетный файл

@ECHO OFF 
set count=0 
:LOOP 
REM To Check the battery status, providing that 1 is discharging 
REM and 2 is connected to the AC 
for /F "delims== tokens=1,2" %%a in (
    'WMIC Path Win32_Battery Get BatteryStatus /format:textvaluelist.xsl' 
) do @if "BatteryStatus"=="%%a" call :DoStaff "%%b" 
:DoStaff 
IF %~1 EQU 2 (
    if %count% NEQ 0 (
     set count=0 
     netsh interface set interface name="Wi-Fi" admin=enabled 
     netsh wlan connect name=GUEST 
     REM will delay execution of the next command by 10 seconds 
     TIMEOUT /T 10 
    ) 
) 
IF %~1 NEQ 2 (
    set /a count=%count%+1 
    if %count% EQU 1 (
     REM Disable the wireless interface 
     netsh interface set interface name="Wi-Fi" admin=disabled 
    ) 
) 
TIMEOUT /T 60 /NOBREAK > nul 
GOTO :LOOP 

Answer 1

@ECHO OFF 
set count=0 
:LOOP 
REM To Check the battery status, providing that 1 is discharging and 2 is connected to the AC 
for /F "delims== tokens=1,2" %%a in ('WMIC Path Win32_Battery Get BatteryStatus /format:textvaluelist.xsl') do @if "BatteryStatus"=="%%a" call :DoStaff "%%b" 

:: You are CALLing the following routine. 
:: IF the routine was to terminate then batch would return to here on termination. 
:: BUT the routine doesn't terminate - it loops back to LOOP 
:: (Which invokes another CALL, loop back to LOOP) ad infinitum 
:: eventually, you run out of stack space and the batch terminates. 

:: Fix : Loop back here 

GOTO LOOP 

:DoStaff 
IF %~1 EQU 2 (
    if %count% NEQ 0 (
    set count=0 
    netsh interface set interface name="Wi-Fi" admin=enabled 
    netsh wlan connect name=EPFL-GUEST 
    REM will delay execution of the next command by 10 seconds 
    TIMEOUT /T 10 
) 
) 
IF %~1 NEQ 2 (
    set /a count=%count%+1 
     if %count% EQU 1 (
     REM Disable the wireless interface 
     netsh interface set interface name="Wi-Fi" admin=disabled 
) 
) 
TIMEOUT /T 60 /NOBREAK > nul 

:: Here you need to terminate the subroutine. 
:: You could simply make thsi end-of-file, 
:: But this following line forces the issue. 
:: note that the colon before EOF is mandatory. 
:: batch understands "GOTO :EOF" to mean, very specifically, 
:: Go To End of physical file 

GOTO :EOF 

:: This following gotoline is not needed. it should be deleted. 
GOTO :LOOP 

Каждый раз, когда вы CALL подпрограмму, добавить еще 1 адрес возврата в стек. Поскольку вы никогда не завершаете подпрограмму (путем достижения конца файла или оператора EXIT), вы в конечном итоге исчерпаете пространство стека.

Answer 2

Если я правильно понял ваш сценарий, вы хотите отключить свой беспроводной адаптер, если компьютер включен, и снова включите его при возврате питания. Моя рекомендация будет сократить код в пакетном скрипте для переключения адаптер включения/выключения:

@echo off 

set "interface=Wi-Fi" 
set "network=EPFL-GUEST" 

REM get battery state (1 => discharging, 2 => connected to AC) 
for /f "delims== tokens=1,2" %%a in (
    'wmic Path Win32_Battery Get BatteryStatus /format:textvaluelist.xsl' 
) do if "BatteryStatus"=="%%a" set "BatteryState=%%b" 

REM get wireless interface state 
for /f "tokens=3" %%a in (
    'netsh interface show interface "%interface%" ^| find /i "administrative state"' 
) do set "InterfaceState=%%~a" 

if %BatteryState% equ 2 (
    if /i "%InterfaceState%"=="disabled" (
     netsh interface set interface name="%interface%" admin=enabled 
     netsh wlan connect name="%network%" 
    ) 
) else if /i "%InterfaceState%"=="enabled" (
    netsh interface set interface name="%interface%" admin=disabled 
) 

и изменить запланированное задание для запуска пакетного сценария (без пусковой VBScript) при запуске, повторяя каждую минуту на неопределенное время ,

Задача также должна быть настроена на запуск того, зарегистрирован пользователь или нет (ваш счет нуждается в "log on as batch job" privilege для этого).

Answer 3

Я предпочитаю Ansgar's solution. Но вы можете заставить свой оригинальный дизайн работать.

Magoo identified why your script eventually fails, но есть дополнительная ошибка в вашей логике.

Вы инициализируете count на 0, что означает, что вы предполагаете, что при запуске подключается как AC, так и WiFi.

Но если AC подключен и WiFi отключен, тогда ваш код никогда не будет включать WiFi.

Вот один из способов устранить проблему.

@echo off 

:: Force the initial iteration to always enable or disable WiFi 
set "priorState=0" 

:LOOP 
for /F "delims== tokens=1,2" %%a in (
    'WMIC Path Win32_Battery Get BatteryStatus /format:textvaluelist.xsl' 
) do if "%%a"=="BatteryStatus" call :DoStuff "%%b" 
goto :LOOP 

:DoStuff 
if %~1 neq %priorState% (
    if %~1 equ 2 (
     %= Connected to AC, so enable WiFi =% 
     netsh interface set interface name="Wi-Fi" admin=enabled 
     netsh wlan connect name=EPFL-GUEST 
    ) else (
     %= Discharging battery, so disable WiFi =% 
     netsh interface set interface name="Wi-Fi" admin=disabled 
    ) 
    set "priorState=%~1" 
) 
timeout /t 60 /nobreak > nul 
exit /b 

можно поместить все в одном бесконечном FOR/L петли, так что не ЗОВ и не GOTO не требуется. Однако необходимо использовать задержанное расширение, чтобы в цикле отображалось изменение значения priorState.

@echo off 
setlocal enableDelayedExpansion 

:: Force the initial iteration to always enable or disable WiFi 
set "priorState=0" 

:: Infinite loop 
for /l %%N in() do (
    for /f "delims== tokens=1,2" %%A in (
    'wmic path Win32_Battery get BatteryStatus /format:textvaluelist.xsl' 
) do if "%%A"=="BatteryStatus" if "%%B" neq "!priorState!" (
    %= Battery state has changed =% 
    if %%B equ 2 (
     %= Connected to AC, so enable WiFi =% 
     netsh interface set interface name="Wi-Fi" admin=enabled 
     netsh wlan connect name=EPFL-GUEST 
    ) else (
     %= Discharging battery, so disable WiFi =% 
     netsh interface set interface name="Wi-Fi" admin=disabled 
    ) 
    set "priorState=%~1" 
) 
    timeout /t 60 /nobreak > nul 
)