Delphi: Обнаружение кнопки колеса мыши нажмите

Question

Что касается компонента TMemo, я не могу найти способ обнаружить, когда пользователь выпустил кнопку WHEEL на своей мыши. Стандартное событие OnMouseUp не реагирует на кнопку колеса мыши.

Answer 1

Этот маленький круг вверх-вниз стрелки является панорамирование окно из VCL, который обеспечивает функциональные возможности прокрутки при нажатии средней кнопки.

Окно панорамирования по умолчанию, TPanningWindow, фиксирует мышь в своем методе StartPanning, чтобы иметь возможность следить за движением мыши и не отпускать ее до тех пор, пока панорамирование не остановится - это вызвано другим щелчком. Вот почему в записке никогда не появляется сообщение средней кнопки, поэтому событие OnMouseUp не запускается.

Вы можете обнаружить сообщение кнопки до того, как оно будет отправлено в окно панорамирования, в обработчике OnMessage «Приложения». Ниже пример кода находится в обработчике событий OnMessage компонента TApplicationEvents, проверяет, извлекается ли сообщение, когда окно панорамирования панорамируется для «Memo1».

uses 
    imouse; 

procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG; 
    var Handled: Boolean); 
begin 
    if (Msg.message = WM_MBUTTONUP) and Assigned(Mouse.PanningWindow) and 
    (Mouse.PanningWindow.HandleAllocated) and 
    (Msg.hwnd = Mouse.PanningWindow.Handle) and 
    (Mouse.PanningWindow is TPanningWindow) and 
    (TPanningWindow(Mouse.PanningWindow).PanControl = Memo1) then 

    // perform what's required 

end; 

---

В качестве альтернативы, вы можете зарегистрировать свой собственный класс окна панорамирования с Mouse.PanningWindowClass, которые могли бы предупредить, что это пан управления для некоторых сообщений. Вот пример:

uses 
    imouse; 

type 
    TMyPanningWindow = class(TPanningWindow) 
    protected 
    procedure WndProc(var Msg: TMessage); override; 
    end; 

{ TMyPanningWindow } 

procedure TMyPanningWindow.WndProc(var Msg: TMessage); 
begin 
    inherited; 
    if (Msg.Msg = WM_MBUTTONUP) and (Assigned(PanControl)) then 
    PanControl.Perform(Msg.Msg, Msg.WParam, Msg.LParam); 
end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    Mouse.PanningWindowClass := TMyPanningWindow; 
end;