Скрытие столбцов в excel на основе значения ячейки

Question

Моя цель - скрыть столбец, если все значения из строки 3-10 равны нулю в этом столбце, поэтому я создаю формулу в строке 11, которая представляет собой сумму значения из строка 3 до 10

Основном я могу создать код, как этот

If Range("B11").Value = 0 Then 
Columns("B:B").EntireColumn.Hidden = True 

Else 

Columns("B:B").EntireColumn.Hidden = False 

End If 

If Range("C11").Value = 0 Then 
Columns("C:C").EntireColumn.Hidden = True 

Else 

Columns("C:C").EntireColumn.Hidden = False 
End If 

, но как только это, потому что я хочу этого макро-бегах от колонки B до FV,

или, может быть любое другое решение для достижения моей цели?

Answer 1

Превосходно цикл будет помогать и присоединиться к функции:

Dim X as Long 
Columns("B:FV").EntireColumn.Hidden = False 
For X = 2 To 178 
    If Join(Application.Transpose(Range(Range(Cells(3, X).Address & ":" & Cells(10, X).Address).Address).Value), "") = "00000000" Then Columns(X).Hidden = True 
Next 

Unhide все столбцы первой, то вы удалили необходимость для еще заявления

Edit: С помощью этого решения вы также дон Вам не нужна ваша формула в строке 11.

Answer 2

Heres в одну сторону.

Sub test() 
Dim iStart As Long:  iStart = Range("B1").Column 
Dim iFin As Long:   iFin = (Range("FV1").Column) - 1 
Dim iCntCol As Long:  iCntCol = iStart 'Col B is #2 
    For iCntCol = iStart To iFin 'FV is Col # 178 
     If Cells(11, iCntCol).Value = 0 Then 
      Columns(iCntCol).EntireColumn.Hidden = True 
      Else 
      Columns(iCntCol).EntireColumn.Hidden = False 
     End If 
    Next iCntCol 
End Sub 

НТН

Answer 3

Я удивлен никто не написать самый простой ответ.

for i = 2 to 178 
    if cells(11, i).value = 0 then 
     Columns(i).EntireColumn.Hidden = True 
    end if 
next 

Answer 4

должен производительности быть проблема, считает, что следует

Option Explicit 

Sub hide() 
Dim found As Range 

With Intersect(ActiveSheet.Range("B11:FV11"), ActiveSheet.UsedRange.EntireColumn) 
    .EntireColumn.Hidden = False 
    .FormulaR1C1 = "=sum(R3C:R10C)" 
    Set found = GetZeroColumns(.Cells, 0) 
End With 
If Not found Is Nothing Then found.EntireColumn.Hidden = True  

End Sub 


Function GetZeroColumns(rng As Range, value As Variant) As Range 
Dim firstAddress As String 
Dim found As Range 

With rng 
    Set found = .Find(What:=value, LookIn:=xlValues, lookat:=xlWhole) 
    If Not found Is Nothing Then 
     firstAddress = found.Address 
     Set GetZeroColumns = found 
     Do 
      Set GetZeroColumns = Union(GetZeroColumns, found) 
      Set found = .FindNext(found) 
     Loop While Not found Is Nothing And found.Address <> firstAddress 
    End If 
End With 
End Function 

Answer 5

Мы могли бы использовать более универсальный код, чтобы сделать это, с помощью не жесткого кодирования диапазона рассмотрения, так что он может быть повторно использован в многие места. Рассмотрим ниже, цикл For...Next будет проверять каждую ячейку в Selection. Selection - текущие выбранные ячейки. Так что просто выберите ячейки, которые вы хотите, чтобы код работал. Если значение ячейки равно 0, то столбец будет помечен для скрытия. Я бы также не рекомендовал скрывать столбец один за другим, это делает код излишне медленным, особенно когда на листе много формул или есть много столбцов, которые нужно скрыть. Итак, что я сделал, просто отметьте столбцы для скрытия с помощью функции Union. Затем спрячьте их за один проход, который вы можете увидеть в последней строке кода.

Sub HideZerosByColumn() 
    Dim iRng As Range 
    Dim uRng As Range 
    Set uRng = Nothing 
    For Each iRng In Selection 
     If iRng = 0 And Not IsEmpty(iRng) Then 
      If uRng Is Nothing Then Set uRng = iRng Else Set uRng = Union(uRng, iRng) 
     End If 
    Next iRng 
    If Not uRng Is Nothing Then uRng.EntireColumn.Hidden = True 
End Sub 

Перед запуском кода выберите диапазон для рассмотрения.

После запуска кода