Выпадающие клавиши массива для вычисления общего количества

Question

Я пытаюсь просто выскочить каждое числовое значение и добавить их вместе, чтобы получить общее количество.

входного файла:

Samsung 46 
RIM  16 
Apple  87 
Microsoft 30 

Мой код компилируется ... он возвращает только 0, хотя.

open (UNITS, 'units.txt') || die "Can't open it $!"; 
my @lines = <UNITS>; 
my $total = 0; 
while (<UNITS>) { 
    chomp; 
    my $line = pop @lines; 
    $line += $total; 
} 
print $total; 

Answer 1

Нет необходимости хлебать все строки в массив, если вы только собираетесь перебрать их так или иначе с while. Кроме того, вам нужно указать split каждую строку, чтобы получить ваши номера.

use warnings; 
use strict; 

open (UNITS, 'units.txt') || die "Can't open it $!"; 
my $total = 0; 
while (<UNITS>) { 
    chomp; 
    my $num = (split)[1]; 
    $total += $num; 
} 
print "$total\n"; 

__END__ 

179 

Answer 2

use strict; 
use warnings; 
open my $fh, "<", "units.txt" or die "well..."; 

my $total = 0; 
while(<$fh>){ 
chomp; 
my ($string, $num) = split(" ", $_); 
$total += $num; 
} 
print $total; 

Answer 3

Есть три проблемы здесь

• Вы пытаетесь добавить строки, как 'Samsung 46' + 'RIM 16'

• Читает весь файл в @lines, а затем попытаться прочитать больше из файл в цикле while. Этот цикл никогда не вводится, потому что вы уже прочитали до конца файла

• Вы добавляете $total к (необъявленной) переменной $line в пределах цикла, а не наоборот. Так $total остается на нуле и $line сохраняет с нулём к нему добавляется

Лучше использовать while для чтения файлов, если вам нужно что-то другое, чем последовательный доступ к записям, поэтому удаление @lines начало.

Непонятно, какую часть записей вы хотите скопировать. Эта программа разбивает строки на пробелы и объединяет последнее поле каждой строки.

Вы должны всегдаuse strict и use warnings в начале каждой программы. Это мера, которая облегчит поиск ошибок в вашем коде. Также лучше использовать лексические файлы, а не глобальные, и трехпараметрическую форму open.

use strict; 
use warnings; 

open my $units, '<', 'units.txt' or die "Can't open it: $!"; 

my $total; 

while (<$units>) { 
    my @fields = split; 
    $total += $fields[-1]; 
} 
print $total; 

выход

179 

Answer 4

Эта проблема является пустяком с однострочника:

$ perl -ane '$sum += $F[1] }{ print $sum' units.txt 

---

Объяснение

• -a позволяет AutoSplit, каждая строка split и хранятся в @F
• -n петель через файл построчно
• -e говорит perl, что следующий аргумент должен рассматриваться как код Perl
• левой части эскимосский поцелуй (этот смешной вид }{ посередине) выполняется для каждой строки во входном файле, RHS выполняется только один раз
• LHS накапливает второй столбец каждой строки в $sum
• RHS выводит результат $sum, когда все линии были обработаны