Inno Setup: автоматически установите флажок после определенного времени в секундах

Question

Здравствуйте, я хочу, чтобы My Inno Setup Script автоматически проверял CheckBox на одной из моих страниц мастера через определенное время (например, 5 секунд).

Вот почему:

Я создал флажок, который может изменить WizardForm «s ClientWidth и ClientHeight при переключении.

Если я не нажму на него, ширина и высота WizardForm останется такой же. Так оно и поступает.

---

Код я написал, чтобы сделать это:

var 
    MinimizerCheckBox: TNewCheckBox; 

procedure InitializeWizard(); 
begin 
    MinimizerCheckBox := TNewCheckBox.Create(WizardForm); 

    with MinimizerCheckBox do 
    begin 
    Name := 'MinimizerCheckBox'; 
    Parent := WizardForm; 
    Left := ScaleX(560); 
    Top := ScaleY(315); 
    Width := ScaleX(90); 
    Height := ScaleY(14); 
    Alignment := taLeftJustify; 
    Caption := 'Compact Mode'; 
    OnClick := @MinimizerCheckBoxClick; 
    TabOrder := 3; 
    end; 
end; 

procedure MinimizerCheckBoxClick(Sender: TObject); 
begin 
    if MinimixerCheckBox.Checked then 
    begin 
    with WizardForm do 
    begin 
     WizardForm.ClientWidth:=420; 
     WizardForm.ClientHeight:=175; 
    end; 
    end else begin 
    with WizardForm do 
    begin 
     WizardForm.ClientWidth:=654; 
     WizardForm.ClientHeight:=407; 
    end; 
    end; 
end; 

Я хочу, чтобы проверить, что флажок автоматически по истечении заданного времени.

Любой пример кода для этого?

Заранее спасибо.

Answer 1

Использовать InnoCallback DLL, чтобы запланировать таймер.

[Files] 
Source: "InnoCallback.dll"; DestDir: "{tmp}"; Flags: dontcopy 

[Code] 

var 
    MinimizerCheckBox: TCheckBox; 

... 

type 
    TTimerProc = procedure(h: LongWord; msg: LongWord; idevent: LongWord; dwTime: LongWord); 

function WrapTimerProc(Callback: TTimerProc; ParamCount: Integer): LongWord; 
    external 'wrapcallback@files:innocallback.dll stdcall'; 
function SetTimer(hWnd: longword; nIDEvent, uElapse: longword; lpTimerFunc: longword): longword; 
    external 'SetTimer@user32.dll stdcall'; 
function KillTimer(hWnd: HWND; uIDEvent: UINT): BOOL; 
    external 'KillTimer@user32.dll stdcall'; 

var 
    CheckTimerID: Integer; 

procedure StopCheckTimer; 
begin 
    Log('Killing timer'); 
    KillTimer(0, CheckTimerID); 
    CheckTimerID := 0; 
end; 

procedure CheckProc(h: LongWord; msg: LongWord; idevent: LongWord; dwTime: LongWord); 
begin 
    Log('Timer elapsed'); 
    StopCheckTimer; 
    MinimizerCheckBox.Checked := True; 
end; 

procedure CurPageChanged(CurPageID: Integer); 
var 
    CheckTimerCallback: LongWord; 
begin 
    if CurPageID = wpXXX then // your page id 
    begin 
    Log('Starting 5s timer'); 
    CheckTimerCallback := WrapTimerProc(@CheckProc, 4); 
    CheckTimerID := SetTimer(0, 0, 5000, CheckTimerCallback); 
    end 
    else 
    if CheckTimerID <> 0 then 
    begin 
    StopCheckTimer; 
    end; 
end;