Получить этап в ActionScript-3 без DisplayObject?

Question

Как я могу получить ссылку на мою сцену без, имеющей объект Sprite/DisplayObject, который уже добавлен на сцену?

---

Дополнительная информация: У меня есть статический класс, который является классом утилиты, и я хочу, чтобы он инициализировался в статическом конструкторе классов, но мне также нужна ссылка на сцену.

public class UtilClass 
{ 
    trace("init: " + stage); 
} 

Первое, что называется в моих AS-3 приложения является конструктор моего основного Sprite/DisplayObject и имеет доступ к сцене. Таким образом, сцена существует в этот момент. Затем Я вызываю утилиты моих UtilClass. Теперь я хочу, чтобы он инициализировался сам по себе при первом использовании (когда этап уже существует).
Я хочу знать, можно ли получить доступ к объекту сцены из любого места без инициализации извне класса утилиты.

Edit:

public class SimpleSprite extends Sprite 
{ 
    public static var aaa:int = 12; 

    public static function test():void 
    { 
     trace("here I am"); 
    } 

    trace(aaa, Capabilities.screenResolutionX+", "+Capabilities.screenResolutionY); 
    test(); 
} 

Answer 1

Упоминание этап доступен в вашем MainTimeline или Main, например, в зависимости от платформы. Вы можете добавить код, чтобы передать эту ссылку другим классам, если вам это нужно. Класс должен иметь метод (статический, в вашем случае), который примет параметр Stage и сохранит его где-нибудь внутри класса.

public class UtilClass { 
    private static var theStage:Stage=null; 
    public static function initialize(s:Stage):void { 
     if (theStage) return; // we're initialized already 
     theStage=s; 
    } 
    // once you call this, you can "trace(theStage)" and get correct output 
    // other methods can also rely on theStage now. 
} 

Затем вы вызываете UtilClass.initialize(stage);, и вы настроены.

Answer 2

Вам нужно будет инициализировать свой UtilClass и передать ссылку на сцену. Я рекомендую вам иметь класс только для ссылки «Управление».

Вы могли бы попробовать что-то вроде этого (просто быстрый пример):

public class StageReference 
{ 
    public static const STAGE_DEFAULT:String = 'stageDefault'; 
    protected static var _stageMap:Dictionary; 

    public static function getStage(id:String = StageReference.STAGE_DEFAULT):Stage 
    { 
     if (!(id in StageReference._getMap())) 
      throw new Error('Cannot get Stage ("' + id + '") before it has been set.'); 

     return StageReference._getMap()[id]; 
    } 

    public static function setStage(stage:Stage, id:String = StageReference.STAGE_DEFAULT):void 
    { 
     StageReference._getMap()[id] = stage; 
    } 

    public static function removeStage(id:String = StageReference.STAGE_DEFAULT):Boolean 
    { 
     if (!(id in StageReference._getMap())) 
      return false; 

     StageReference.setStage(null, id); 

     return true; 
    } 

    protected static function _getMap():Dictionary 
    { 
     if (!StageReference._stageMap) StageReference._stageMap = new Dictionary(); 

     return StageReference._stageMap; 
    } 
} 

При запуске приложения (главный класс или где вы начинаете включать логику)

StageReference.setStage(stage); 

И когда вам необходимо получить ссылку на эталон

trace('Checking the Stage: ', StageReference.getStage());