Добавление пространства имен только к одному элементу

Question

Как добавить пространство имен в корневой элемент?

Мой XML:

<Envelope> 
    <from> 
     <contents /> 
    </from> 
</Envelope> 

Мой желаемый результат:

<Envelope xmlns:tns="Foo"> 
    <from> 
     <contents /> 
    </from> 
</Envelope> 

я могу получить только "Xmlns = 'Foo'", используя это, а не "Xmlns: ТНС = ..":

<xsl:element name="{local-name()}" namespace="Foo" > 
     <xsl:copy-of select="attribute::*"/> 
     <xsl:apply-templates /> 
</xsl:element> 

Answer 1

Вот полное преобразование:

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:tns="Foo"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="/*"> 
     <xsl:element name="{name()}"> 
     <xsl:copy-of select= 
     "document('')/*/namespace::*[name()='tns']"/> 
     <xsl:apply-templates/> 
     </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

Когда это преобразование применяется на поставленном XML документа:

<Envelope> 
    <from> 
     <contents /> 
    </from> 
</Envelope> 

разыскиваемый, правильный результат получается:

<Envelope xmlns:tns="Foo"> 
    <from> 
     <contents/> 
    </from> 
</tns:Envelope>