XML и XSLT keep CDATA

Question

Я работаю над проектом, который включает в себя применение некоторых xslt для xml.

My Input xml содержит «CDATA» в любом из узлов xml.

Теперь то, что я хочу, это должно держать «CDATA», если он имеет на входе

Я пробовал много решений, как отключить-выход-отводящей и CDATA-секции-элементов и т.д. ... , но я не нашел ни одного из они подходят для моего требования.

Итак, есть ли способ, я могу это сделать ?? Если входные узлы xml имеют cdata, тогда он должен указывать его на выходе, если входные узлы xml не имеют cdata, тогда он не должен давать его на выходе.

Я узел называется, который содержит CDATA и другой узел в некотором дифф месте, которое не суммируется и не содержит CDATA ..

<Address> 
<Location> 
<Code>912</Code> 
<Value>10301</Value> 
</Location> 
<Name><![CDATA[E&S]]></Name> 
<CompanyName><![CDATA[E&S]]></CompanyName> 
<AddressLine3>dummy address</AddressLine3> 
<City>dummy city</City> 
<State>dummy state</State> 
<PostalCode>dummy postal code</PostalCode> 
<Country>dummy country</Country> 
</Address> 
<Nodes> 
<Node> 
<Type>CTU</Type> 
<Text><![CDATA[dummy text & dummy Text.]]></Text> 
</Node> 
</Nodes> 

Это не зафиксировано, что только заранее определенные узлы будут содержать CDATA он может прийти в любом месте

Answer 1

Вот краткий пример того, как это делается:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes" 
cdata-section-elements="a b c d e"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 
</xsl:stylesheet> 

Когда это преобразование применяется на следующий документ XML:

<Record> 
    <a>10:30</a> 
    <b>20:30</b> 
    <c>10:60</c> 
    <d>1:15</d> 
    <e>1:03</e> 
</Record> 

разыскиваемый, правильный результат получается:

<Record> 
    <a><![CDATA[10:30]]></a> 
    <b><![CDATA[20:30]]></b> 
    <c><![CDATA[10:60]]></c> 
    <d><![CDATA[1:15]]></d> 
    <e><![CDATA[1:03]]></e> 
</Record> 

В случае множество имен элементов не известны заранее, можно использовать таблицу стилей, которая создает другую таблицу стилей, которая должна быть окончательно применена к документу XML для получения желаемого результата.:

<xsl:stylesheet version="1.0" xmlns:x="http://www.w3.org/1999/XSL/Transform" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xxx="xxx"> 
<xsl:namespace-alias stylesheet-prefix="xxx" result-prefix="xsl"/> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:key name="kElemByName" match="*[text()[normalize-space()]]" use="name()"/> 

<xsl:variable name="vDistinctNamedElems" select= 
"//*[generate-id()=generate-id(key('kElemByName',name())[1])]"/> 

<xsl:variable name="vDistinctNames"> 
    <xsl:for-each select="$vDistinctNamedElems"> 
    <xsl:value-of select="concat(name(), ' ')"/> 
    </xsl:for-each> 
</xsl:variable> 

<xsl:template match="node()|@*"> 
    <xxx:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xxx:output omit-xml-declaration="yes" indent="yes" 
     cdata-section-elements="{$vDistinctNames}"/> 
    <xxx:strip-space elements="*"/> 

    <xxx:template match="node()|@*"> 
    <xxx:copy> 
     <xxx:apply-templates select="node()|@*"/> 
    </xxx:copy> 
    </xxx:template> 
    </xxx:stylesheet> 
</xsl:template> 
</xsl:stylesheet> 

Когда это преобразование применяется на документе же XML (выше), то результат будет другой XSLT-таблица стилей:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:x="http://www.w3.org/1999/XSL/Transform" 
       version="1.0"> 
    <xsl:output omit-xml-declaration="yes" indent="yes" cdata-section-elements="a b c d e "/> 
    <xsl:strip-space elements="*"/> 
    <xsl:template match="node()|@*"> 
     <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

В этой таблице стилей все имена элементов в атрибуте cdata-section-elements, генерируются динамически (используя метод Muenchian для группировки).

Когда мы, наконец, применить полученные таким образом таблицы стилей XSLT на тот же самом документе XML, мы получаем желаемый результат:

<Record> 
    <a><![CDATA[10:30]]></a> 
    <b><![CDATA[20:30]]></b> 
    <c><![CDATA[10:60]]></c> 
    <d><![CDATA[1:15]]></d> 
    <e><![CDATA[1:03]]></e> 
</Record> 

Объяснения:

1. Динамически производству нового преобразование, с использованием инструкции XSLT xsl:namespace-alias ,

2. Muenchian grouping для определения всех различных наименований элементов.

Answer 2

Ваше решение ввести имя вашего узла/элемента, который содержит cdatasection в cdata-section-elements атрибуту (uh):

<xsl:output omit-xml-declaration="yes" 
      indent="yes" 
      cdata-section-elements="Name CompanyName Text" 
/>