Вывести номер строки, когда есть совпадающее значение для каждого столбца

Question

Say У меня file.txt

Position name1 name2 name3 
     2  A  G  F 
     4  G  S  D 
     5  L  K  P 
     7  G  A  A 
     8  O  L  K 
     9  E  A  G 

и мне нужно, чтобы получить выход:

name1 name2 name3 
    2  2  7 
    4  7  9 
    7  9 

Он выводит каждое имя и номера позиций, где есть A или G

В файле file.txt столбец name1 имеет A в позиции 2, G в позициях 4 и 7 ... поэтому в выходном файле: 2, 4,7 указана под именем1 ... и т. Д.

Стратегия, которую я разработал до сих пор (не очень эффективный): чтение каждого столбца по одному и вывод номера позиции при совпадении. Затем я получаю результат для каждого столбца и свяжу их вместе, используя r.

Я уверен, что есть лучший способ использовать awk или bash ... идеи оценены.

Answer 1

$ cat tst.awk 
NR==1 { 
    for (nameNr=2;nameNr<=NF;nameNr++) { 
     printf "%5s%s", $nameNr, (nameNr<NF?OFS:ORS) 
    } 
    next 
} 
{ 
    for (nameNr=2;nameNr<=NF;nameNr++) { 
     if ($nameNr ~ /^[AG]$/) { 
      hits[nameNr,++numHits[nameNr]] = $1 
      maxHits = (numHits[nameNr] > maxHits ? numHits[nameNr] : maxHits) 
     } 
    } 
} 
END { 
    for (hitNr=1; hitNr<=maxHits; hitNr++) { 
     for (nameNr=2;nameNr<=NF;nameNr++) { 
      printf "%5s%s", hits[nameNr,hitNr], (nameNr<NF?OFS:ORS) 
     } 
    } 
} 

$ awk -f tst.awk file 
name1 name2 name3 
    2  2  7 
    4  7  9 
    7  9 

Answer 2

Сохранить ниже скрипт:

#!/bin/bash 
gawk '{if(NR == 1) {print $2 >>"name1"; print $3 >>"name2"; print $4>>"name3";}} 
     {if($2=="A" || $2=="G"){print $1 >> "name1"}} 
     {if($3=="A" || $3=="G"){print $1 >> "name2"}} 
     {if($4=="A" || $4=="G"){print $1 >> "name3"}} 
     END{system("paste name*;rm name*")}' $1 

как finder. Сделать искатель исполняемого (используя CHMOD), а затем сделать:

./finder file.txt 

Примечание: я использовал три временные файлы name1, name2 и NAME3. Вы можете изменить имена файлов в удобное для вас время. Кроме того, эти файлы будут удалены в конце.

Редактировать: Удалить BEGIN часть gawk.