Использование fortran для передачи функций в подпрограмму.

Question

Я написал набор подпрограмм и скомпилировал их в библиотеку. Эти подпрограммы основаны на некоторой определенной функции (x, y). На данный момент это похоронено внутри подпрограммы библиотеки, однако мне хотелось бы передать любую функцию (x, y) в эту библиотеку - возможно ли это? Спасибо, парни!

Answer 1

module ExampleFuncs 

    implicit none 

abstract interface 
    function func (z) 
     real :: func 
     real, intent (in) :: z 
    end function func 
end interface 


contains 


subroutine EvalFunc (aFunc_ptr, x) 

    procedure (func), pointer :: aFunc_ptr 
    real, intent (in) :: x 

    write (*, *) "answer:", aFunc_ptr (x) 

end subroutine EvalFunc 


function f1 (x) 
    real :: f1 
    real, intent (in) :: x 

    f1 = 2.0 * x 

end function f1 


function f2 (x) 
    real :: f2 
    real, intent (in) :: x 

    f2 = 3.0 * x**2 

end function f2 

end module ExampleFuncs 


program Func_to_Sub 

    use ExampleFuncs 

    implicit none 

    procedure (func), pointer :: f_ptr => null() 

    f_ptr => f1 
    call EvalFunc (f_ptr, 2.0) 

    f_ptr => f2 
    call EvalFunc (f_ptr, 2.0) 

    stop 

end program Func_to_Sub