Пакетный файл для проверки наличия файла на определенное время

Question

Новое для пакетного сценария. Пытаясь написать скрипт, который проверяет файлы с именем файла, начинающимся с LEND, путем опроса каталога, и если файл не получен в 17:30, напишите сообщение журнала в файл журнала. Я написал приведенный ниже пакетный скрипт, сценарий работает нормально, пока в каталоге нет файлов. Как только я помещаю файлы туда, он перестает работать. И перезапускается, если я удалю файлы из этого каталога. Не могли бы вы посоветовать, где я ошибаюсь? Благодаря

@echo off 

set I=0 
set log=C:\logs\alerting.log 

:recurse 
for /f %%P in ('dir /b "C:\incoming\LEND*"') do (call :countfiles) 
set Time=%time:~0,5% 
echo Filecount: %I% at Time: %Time% >> %log% 
if %Time%==17:30 goto OUT 
pause 60 
goto :recurse 

:countfiles 
set /a I+=1 

:OUT 
if %I%==0 echo LEND Files not received >> %log% 
EXIT 

Answer 1

Ваш код идет от countfiles к выходу. Попробуйте это:

:countfiles 
set /a I+=1 
goto:eof 

Answer 2

Были на самом деле несколько недостатков - повторное использование переменного времени, ожидая паузы, чтобы использовать в качестве задержки, временные рамки могли быть пропущены в тесте, и другие более мелкие вещи.

Это проверяется, насколько подсчет файлов идет, но не филиал 17:30

Я изменил стиль несколько команд и имен переменных (я слишком много, как и я л и 1 во многих шрифтах)

@echo off 

set log=C:\logs\alerting.log 

:loop 
for /f %%P in ('dir /b "C:\incoming\LEND*" 2^>nul ^| find /c /v "" ') do set c=%%P 
set now=%time:~0,5% 
echo Filecount: %c% at Time: %now% 
echo Filecount: %c% at Time: %now% >> %log% 
if %now:~0,2%%now:~3,2% GTR 1730 goto :OUT 
ping -n 60 localhost >nul 
goto :loop 

:OUT 
if %c% EQU 0 echo LEND Files not received >> %log% 
EXIT