XSLT - нужна помощь для преобразования в неопределенный формат JSON

Question

У меня есть требование, когда я хочу преобразовать данные внутренней таблицы в формат JSON.

Предположим, что мое внутреннее имя таблицы ZEMPLOYEE и поля в нем: EMPID, ENAME, ESAL. Нормальное преобразование вызова преобразует его в формат ниже.

Данные- [{EmpId: 101, ENAME: 'ABCD', ESAL: 100}, {EmpId: 102, ENAME: 'EFGH', ESAL: 200}, {EmpId: 103, ENAME: 'IJKL », ESAL: 300}]

Но мое требование формат вывода должен выглядеть следующим образом:

Данные- [{EmpId, ENAME, ESAL}, {101, ABCD, 100}, {102, EFGH, 200}, {103, IJKL, 300}] ...

Где ель st фигурные скобки будут содержать поля моей таблицы, а оставшиеся фигурные скобки содержат фактические данные.

Может ли кто-нибудь помочь мне достичь вышеуказанного результата с помощью преобразования XSLT или простого преобразования?

Answer 1

Что вы показываете нам, гораздо ближе к CSV, чем к JSON. Попробуйте что-то вроде:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text" encoding="UTF-8"/> 

<xsl:template match="/*"> 
    <!-- header --> 
    <xsl:text>Data-[{</xsl:text> 
    <xsl:for-each select="*[1]/*"> 
     <xsl:value-of select="local-name()"/> 
     <xsl:if test="position()!=last()"> 
      <xsl:text>,</xsl:text> 
     </xsl:if> 
    </xsl:for-each> 
    <xsl:text>},</xsl:text> 

    <!-- data --> 
    <xsl:for-each select="*"> 
     <xsl:text>{</xsl:text> 
     <xsl:for-each select="*"> 
      <xsl:value-of select="."/> 
      <xsl:if test="position()!=last()"> 
       <xsl:text>,</xsl:text> 
      </xsl:if> 
     </xsl:for-each> 
     <xsl:text>}</xsl:text> 
     <xsl:if test="position()!=last()"> 
      <xsl:text>,</xsl:text> 
     </xsl:if> 
    </xsl:for-each> 
    <xsl:text>]</xsl:text> 
</xsl:template> 

</xsl:stylesheet> 

При нанесении на хорошо сформированный входной например в (!):

<FLIGHT_TABLE> 
    <ZSCARR_LINE> 
    <CARRID>AA</CARRID> 
    <CARRNAME>American Airlines</CARRNAME> 
    <CURRCODE>USD</CURRCODE> 
    </ZSCARR_LINE> 
    <ZSCARR_LINE> 
    <CARRID>AB</CARRID> 
    <CARRNAME>Air Berlin</CARRNAME> 
    <CURRCODE>EUR</CURRCODE> 
    </ZSCARR_LINE> 
    <ZSCARR_LINE> 
    <CARRID>AC</CARRID> 
    <CARRNAME>Air Canada</CARRNAME> 
    <CURRCODE>CAD</CURRCODE> 
    </ZSCARR_LINE> 
    <ZSCARR_LINE> 
    <CARRID>AF</CARRID> 
    <CARRNAME>Air France</CARRNAME> 
    <CURRCODE>EUR</CURRCODE> 
    </ZSCARR_LINE> 
</FLIGHT_TABLE> 

результат будет:

Data-[{CARRID,CARRNAME,CURRCODE},{AA,American Airlines,USD},{AB,Air Berlin,EUR},{AC,Air Canada,CAD},{AF,Air France,EUR}]