Перемещение кластеров с течением времени

Question

Я пытаюсь провести анализ кластеров на основе транзакционных данных для финансового продукта и попытаться измерить их движение с течением времени. У меня готов статический кластер (на основе транзакций в первом квартале). Теперь я хочу видеть их движение во втором квартале и посмотреть, остаются ли они в том же кластере или переходят в другой кластер. У меня есть кластерное значение и радиус для каждого кластера, а затем измеряется расстояние от новых транзакционных показаний до центроидов кластера и соответственно группировать их. Но я не уверен, как измерить это расстояние.

Я использую SAS для своего анализа.

Answer 1

Вот пример использования proc fastclus.

/* Create initial clusters */ 
proc fastclus 
     data = sashelp.class 
     /* Output the cluster for each observation */ 
     out = cluster1 
     maxclusters = 2 
     /* Output the centroids */ 
     outseed = seed1; 
    var age height weight; 
run; 
/* Move the numbers around a bit to simulate a later snapshot */ 
data class2; 
    set cluster1; 
    drop distance; 
    rename cluster = cluster1; 
    age + rand("normal", 0, 5); 
    height + rand("normal", 0, 5); 
    weight + rand("normal", 0, 5); 
run; 
/* Apply the original clustering to the new data */ 
proc fastclus 
     data = class2 
     /* This output will contain the cluster and distance */ 
     out = cluster2 
     maxclusters = 2 
     /* Pass the initial centroids */ 
     seed = seed1 
     /* Output the new cluster centroids */ 
     outseed = seed2 
     /* Prevent looking for better clusterings, change this if you want better clusters */ 
     maxiter = 0; 
    var age height weight; 
run;