Нужна помощь в слиянии двух макросов для Excel VBA

Question

Оба этих макроса - это макросы, которые я нашел в Интернете и адаптированы для моего использования. Я использую этот код и он работает хорошо, чтобы отделить конкретные данные в новые листы:

 Sub Copy_To_Worksheets() 
'Note: This macro use the function LastRow 
    Dim My_Range As Range 
    Dim FieldNum As Long 
    Dim CalcMode As Long 
    Dim ViewMode As Long 
    Dim ws2 As Worksheet 
    Dim Lrow As Long 
    Dim cell As Range 
    Dim CCount As Long 
    Dim WSNew As Worksheet 
    Dim ErrNum As Long 

    'Set filter range on ActiveSheet: A1 is the top left cell of your filter range 
    'and the header of the first column, D is the last column in the filter range. 
    'You can also add the sheet name to the code like this : 
    'Worksheets("Sheet1").Range("A1:D" & LastRow(Worksheets("Sheet1"))) 
    'No need that the sheet is active then when you run the macro when you use this. 


    Set My_Range = Range("A1:Z" & Range("A" & Rows.Count).End(xlUp).Row) 
    My_Range.Parent.Select 

    If ActiveWorkbook.ProtectStructure = True Or _ 
     My_Range.Parent.ProtectContents = True Then 
     MsgBox "Sorry, not working when the workbook or worksheet is protected", _ 
       vbOKOnly, "Copy to new worksheet" 
     Exit Sub 
    End If 

    'This example filters on the first column in the range(change the field if needed) 
    'In this case the range starts in A so Field:=1 is column A, 2 = column B, ...... 
    FieldNum = 5 'I changed this to 3 for column C 

    'Turn off AutoFilter 
    My_Range.Parent.AutoFilterMode = False 

    'Change ScreenUpdating, Calculation, EnableEvents, .... 
    With Application 
     CalcMode = .Calculation 
     .Calculation = xlCalculationManual 
     .ScreenUpdating = False 
     .EnableEvents = False 
    End With 
    ViewMode = ActiveWindow.View 
    ActiveWindow.View = xlNormalView 
    ActiveSheet.DisplayPageBreaks = False 

    'Add a worksheet to copy the a unique list and add the CriteriaRange 
    Set ws2 = Worksheets.Add 

    With ws2 
     'first we copy the Unique data from the filter field to ws2 
     My_Range.Columns(FieldNum).AdvancedFilter _ 
       Action:=xlFilterCopy, _ 
       CopyToRange:=.Range("A1"), Unique:=True 

     'loop through the unique list in ws2 and filter/copy to a new sheet 
     Lrow = .Cells(Rows.Count, "A").End(xlUp).Row 
     For Each cell In .Range("A2:A" & Lrow) 

      'Filter the range 
      My_Range.AutoFilter Field:=FieldNum, Criteria1:="=" & _ 
      Replace(Replace(Replace(cell.Value, "~", "~~"), "*", "~*"), "?", "~?") 

      'Check if there are no more then 8192 areas(limit of areas) 
      CCount = 0 
      On Error Resume Next 
      CCount = My_Range.Columns(1).SpecialCells(xlCellTypeVisible) _ 
        .Areas(1).Cells.Count 
      On Error GoTo 0 
      If CCount = 0 Then 
       MsgBox "There are more than 8192 areas for the value : " & cell.Value _ 
        & vbNewLine & "It is not possible to copy the visible data." _ 
        & vbNewLine & "Tip: Sort your data before you use this macro.", _ 
         vbOKOnly, "Split in worksheets" 
      Else 
       'Add a new worksheet 
       Set WSNew = Worksheets.Add(After:=Sheets(Sheets.Count)) 
       On Error Resume Next 
       WSNew.Name = cell.Value 
       If Err.Number > 0 Then 
        ErrNum = ErrNum + 1 
        WSNew.Name = "Error_" & Format(ErrNum, "0000") 
        Err.Clear 
       End If 
       On Error GoTo 0 

       'Copy the visible data to the new worksheet 
       My_Range.SpecialCells(xlCellTypeVisible).Copy 
       With WSNew.Range("A1") 
        ' Paste:=8 will copy the columnwidth in Excel 2000 and higher 
        ' Remove this line if you use Excel 97 
        .PasteSpecial Paste:=8 
        .PasteSpecial xlPasteValues 
        .PasteSpecial xlPasteFormats 
        Application.CutCopyMode = False 
        .Select 
       End With 
      End If 

      'Show all data in the range 
      My_Range.AutoFilter Field:=FieldNum 

     Next cell 

     'Delete the ws2 sheet 
     On Error Resume Next 
     Application.DisplayAlerts = False 
     .Delete 
     Application.DisplayAlerts = True 
     On Error GoTo 0 

    End With 

    'Turn off AutoFilter 
    My_Range.Parent.AutoFilterMode = False 

    If ErrNum > 0 Then 
     MsgBox "Rename every WorkSheet name that start with ""Error_"" manually" _ 
      & vbNewLine & "There are characters in the name that are not allowed" _ 
      & vbNewLine & "in a sheet name or the worksheet already exist." 
    End If 

    'Restore ScreenUpdating, Calculation, EnableEvents, .... 
    My_Range.Parent.Select 
    ActiveWindow.View = ViewMode 
    With Application 
     .ScreenUpdating = True 
     .EnableEvents = True 
     .Calculation = CalcMode 
    End With 
    End Sub 

Что мне нужна помощь, чтобы добавить определенный набор формул в нижней части каждого листа, который создается из приведенного выше макроса , Следующий макрос добавляет формулы ко всем листам в книге. Мне нужно это, чтобы добавить формулы только к листам, созданным в вышеуказанном макросе. Количество создаваемых листов изменяется каждый раз, когда они создаются, в зависимости от исходных данных. Я думал, что лучше всего объединить нижний макрос в верх, но я не знаю, как это сделать.

Sub Insert_Formulas() 
    Dim ws As Worksheet 

    For Each ws In ThisWorkbook.Worksheets 
    ws.Activate 

    'Start 
    NxtRw = Cells(Rows.Count, "B").End(xlUp).Row + 1 
    With Cells(NxtRw, "B") 
    .Value = "Total Open Cases" 
    End With 

    With Cells(NxtRw, "C") 
     .EntireRow.Insert 
     .Value = "Total Closed Cases" 
    End With 

    'Next Row below 
    NxtRw = Cells(Rows.Count, "B").End(xlUp).Row + 1 
    With Cells(NxtRw, "B") 
    .Formula = "=CountIf(B2:B" & NxtRw - 1 & ", ""Open*"")" 
    End With 

    With Cells(NxtRw, "C") 
    .Formula = "=CountIf(B2:B" & NxtRw - 1 & ", ""Closed*"")" 
    End With 
    Next 
End Sub 

Любая помощь была бы принята с благодарностью.

Спасибо, Ck

Answer 1

Если вы Параметризуете функцию так, что она принимает лист, требующие формулы в качестве параметра

Sub Insert_Formulas_Into_WorkSheet(ws As Worksheet) 

    ws.Activate 

    'Start 
    NxtRw = Cells(Rows.Count, "B").End(xlUp).Row + 1 
    With Cells(NxtRw, "B") 
    .Value = "Total Open Cases" 
    End With 

    With Cells(NxtRw, "C") 
     .EntireRow.Insert 
     .Value = "Total Closed Cases" 
    End With 

    'Next Row below 
    NxtRw = Cells(Rows.Count, "B").End(xlUp).Row + 1 
    With Cells(NxtRw, "B") 
    .Formula = "=CountIf(B2:B" & NxtRw - 1 & ", ""Open*"")" 
    End With 

    With Cells(NxtRw, "C") 
    .Formula = "=CountIf(B2:B" & NxtRw - 1 & ", ""Closed*"")" 
    End With 
End Sub 

Затем вы можете добавить формулы после каждого новый рабочего листа создаются вызов

Insert_Formulas_Into_WorkSheet WSNew 

Answer 2

Я бы не объединить 2 макросы, просто вызовите Insert_Formulas макрос из Copy_To_Worksheets макроса, когда это необходимо.

Для вызова макроса все, что вам нужно это строка:

Insert_Formulas 

Редактировать, чтобы ответить на комментарий:

Учитывая вы не знаете, сколько листов добавляются у меня есть одно предложение вы можете попробовать.

Высокий уровень, добавьте текст в ячейку на каждом листе, чтобы указать, является ли оно новым или нет. Когда новый лист создается, ячейка должна указывать «новый». Если не новый, он должен сказать «существующий». Затем в

Если вы хотите дать это, попробуйте, и дайте мне знать, что не работает. Я могу проверить и помочь обновить код.

1. В Copy_To_Worksheets макрос вам необходимо добавить строку, чтобы установить все существующие листы «существующие»
2. В то Copy_To_Worksheets макрос добавить строку, так что новые листы приготовьтесь к «новой»
3. В макросе Insert_Formulas все еще прокручивайте все листы, но проверяйте, является ли лист «новым», и если да, запустите код, чтобы добавить формулы.

Более чистым (но немного более сложным) вариантом будет определение имени на каждом листе (одно имя для каждого и ограничение объема для каждого отдельного листа) и использование этого вместо ячейки на каждом листе ,