Копирование (только значение, а не формула) диапазон ячеек на другой лист в том же файле

Question

Я использую следующий код. Этот код копирует формулы ячейки в другой лист. Кто-нибудь знает, как я могу изменить его, чтобы просто скопировать значения ячеек, а не формулы?

---

sub copyRangeOver() 

    Dim i As Integer 
    i = 631 

    Dim copyRange As Range 
    Set copyRange = ThisWorkbook.Worksheets("Coupling xyz data").Range("J" & 1 & ":V" & i) 

    Dim countD As Integer 
    countD = 1 
    copyRange.Copy Destination:=Cells(countD, 1) 

    Dim j As Integer 
    j = 466 
    Set copyRange = ThisWorkbook.Worksheets("Spring xyz data").Range("J" & 1 & ":V" & j) 

    copyRange.Copy Destination:=Cells(i + 1, 1) 

End Sub 

Answer 1

Вы можете сделать перевод прямое значение, которое быстрее, чем Copy и Paste Special, значения и не связаны с буфером обмена.

Sub copyRangeOver() 

    Dim i As Long, j As Long, countD As Long 
    Dim copyRange As Range 

    i = 631 
    countD = 1 

    With ThisWorkbook.Worksheets("Coupling xyz data") 
     Set copyRange = .Range("J" & 1 & ":V" & i) 
     Cells(countD, 1).Resize(copyRange.Rows.Count, copyRange.Columns.Count) = _ 
      copyRange.Value 
    End With 

    j = 466 

    With ThisWorkbook.Worksheets("Spring xyz data") 
     Set copyRange = .Range("J" & 1 & ":V" & j) 
     Cells(i + 1, 1).Resize(copyRange.Rows.Count, copyRange.Columns.Count) = _ 
      copyRange.Value 
    End With 

End Sub 

Это дублирует предыдущие усилия, хотя мне кажется, что есть некоторая неясность в пункте назначения (ы) значений. Для строки, принимающей значения, вы используете i во втором и CountD в первом, но между ними нет связи.

Answer 2

Вам нужно pastespecial:

copyRange.Copy 
Cells(countD, 1).PasteSpecial Paste:=xlPasteValues 

Answer 3

Это нормально, как это делается.

copyRange.Copy 
    Cells(i + 1, 1).PasteSpecial xlPasteValues 
    application.cutcopymode=0