Пакетный скрипт для удаления дубликатов строк, но хотел игнорировать/пропустить некоторые строки

Question

Это также можно игнорировать некоторые повторяющиеся строки в то время как удаление других дубликатов из файла XML, пример: если мой abx.xml является КОД:

@echo off 
setlocal disableDelayedExpansion 
set "file=%~1" 
set "line=%file%.line" 
set "deduped=%file%.deduped" 
::Define a variable containing a linefeed character 
set LF=^ 


::The 2 blank lines above are critical, do not remove 
>"%deduped%" (
    for /f usebackq^ eol^=^%LF%%LF%^ delims^= %%A in ("%file%") do (
    set "ln=%%A" 
    setlocal enableDelayedExpansion 
    >"%line%" (echo !ln:\=\\!) 
    >nul findstr /xlg:"%line%" "%deduped%" || (echo !ln!) 
    endlocal 
) 
) 
>nul move /y "%deduped%" "%file%" 
2>nul del "%line%" 

Только BATCH SCRIPT ПОЖАЛУЙСТА.

<bookstores> 
    <book id="parent"> 
     <name="it1"/> 
     <name="it1"/> 
     <name="it2"/> 
    </book> 
    <book id="child"> 
     <name="it1"/> 
     <name="it1"/> 
     <name="it2"/> 
     <name="it3"/> 
    </book>  
</bookstores> 

Вывод должен быть:

<bookstores> 
    <book id="parent"> 
     <name="it1"/> 
     <name="it2"/> 
    </book> 
    <book id="child"> 
     <name="it3"/> 
    </book>  
</bookstores> 

Но выход я получаю: Примечание:</book> тег удаляется.

<bookstores> 
    <book id="parent"> 
     <name="it1"/> 
     <name="it2"/> 
    </book> 
    <book id="child"> 
     <name="it3"/> 

</bookstores> 

Я искал пару предложения этого типа запросов, но большинство из них удалить все повторяющиеся строки, но не уверен, как игнорировать некоторые повторяющиеся строки:

Batch to remove duplicate rows from text file

Answer 1

Это может работать для вас, если вы помещаете линии всегда печатать в %dict% файле:

@ECHO OFF &SETLOCAL ENABLEDELAYEDEXPANSION 
SET "file=file" 
SET "new=new" 
SET "dict=dictionary" 

(FOR /f "tokens=1*delims=:" %%a IN ('findstr /n "^" "%file%"') DO (
    SET "nr=%%a" 
    SET "line=%%b" 
    SET "this=" 
    FINDSTR /l "!line!" "%dict%" >NUL 2>&1&& ECHO(!line! || (
     FOR /f "tokens=1*delims==" %%x IN ('set "$" 2^>nul') DO IF !line!==%%y SET "this=1" 
     IF "!this!"=="" (
      ECHO(!line! 
      SET "$!nr!=!line!" 
     ) 
    ) 
))>"%new%" 
TYPE "%new%" 

..she ll session:

>type file 
    <bookstores> 
     <book id="parent"> 
      <name="it1"/> 
      <name="it1"/> 
      <name="it2"/> 
     </book> 
     <book id="child"> 
      <name="it1"/> 
      <name="it1"/> 
      <name="it2"/> 
      <name="it3"/> 
     </book> 
    </bookstores> 

    >type dictionary 
    </book> 

    >script.bat 
    <bookstores> 
     <book id="parent"> 
      <name="it1"/> 
      <name="it2"/> 
     </book> 
     <book id="child"> 
      <name="it3"/> 
     </book> 
    </bookstores>