Реферирование путь работы и имя в SAS ГНР

Question

В SAS ГНР, я хочу, чтобы ссылаться на имя задания в коде. Я знаю, что глобальная переменная etls_jobName содержит эту информацию, но когда я присваиваю это значение полю и просматриваю вывод, я получаю «.».

В конце концов, я хотел бы также иметь возможность получить путь к файлу (в структуре папок на работу), и я не уверен, где такого рода информации, живет.

Большая благодарность.

Answer 1

Для пути метаданных потока задания, вы можете попробовать использовать следующий код. Код подхватывает имя задания из & etls_jobName макропеременной и извлекает метаданные путь к папке задания. Чтобы узнать больше о функциях, которые используются, обратитесь к интерфейсам языка SAS к метаданным. Надеюсь это поможет!

data path_output; 
    length jobName $ 100 uri headuri $ 256 jobPath head_path $ 500 ; 

    jobName="&etls_jobName"; 
    rcJob =metadata_getnobj("omsobj:Job?@Name ='&etls_jobName'",1,uri); 
    rcHead=metadata_getnasn(uri,"Trees",1,headuri); 
    rcPath=metadata_getattr(headuri,"Name",jobPath); 

    rcHead = 1; 
    do while(rcHead>0); 
     rcHead=metadata_getnasn(headuri,"ParentTree",1,headuri); 
     rcPath=metadata_getattr(headuri,"Name",head_path); 

     if (rcHead>0) then jobPath = catx('/',head_path,jobPath); 
    end; 

    output; 
    keep jobName jobPath; 
run; 

proc print; 
run; 

UPDATE:

Если Job Flow URI должен быть выбран на основе имени потока Работа затем использовать то, что показывают в коде выше, а именно:

rcJob =metadata_getnobj("omsobj:Job?@Name ='&etls_jobName'",1,uri); 

Если работы потока URI необходимо выбрать на основе идентификатора метаданных, а затем использовать:

rcJob =metadata_getnobj("omsobj:Job?@Id ='&jobID'",1,uri);