Схема структуры с другой структурой

Question

Я пытаюсь изучить схему (drracket) самостоятельно, и у меня возникла проблема.

Я пытаюсь работать с различными формами, такими как круги, квадраты и прямоугольники. Задача заключается в следующем:.

«Определить типы„круг“,„квадрат“и„прямоугольник“и определить основную типа„форма“ мне нужно-структуру формы для следующей части задания где Я должен определить функцию «область из формы», который получает «форму» databundle и который, как предполагается, представляют область любой заданной формы

Вот то, что я до сих пор:.

(define-struct square (nw lenght)) 

(define-struct circle (center radius)) 

(define-struct rectangle (nw width height)) 

(define-struct shape (...)) 



(define (area-of-shape shapeA) 
    (cond 
    [(square? (shapeA)) (* (square-lenght shapeA) (square-lenght shapeA))] 
    [(circle? (shapeA)) (* 3.14 (* (circle-radius shapeA) (circle-radius shapeA)))] 
    [(rectangle? (shapeA)) (* (rectangle-width shapeA) (rectangle-height shapeA))])) 

Как определить структуру shape? Я пробовал что-то вроде

(define-struct shape (circle square rectangle))

Но это не имеет никакого смысла, поскольку для структуры понадобится все 3 формы.

Любая помощь будет оценена по достоинству.

Answer 1

Ракетка могут наследовать Структуры от другой структуры. Итак:

#lang racket 

(struct shape()) 
(struct square shape (nw length)) 
(struct circle shape (center radius)) 
(struct rectangle shape (nw width height)) 

(define (area-of-shape shape) 
    (if (shape? shape) 
    (cond 
     [(square? shape) (* (square-length shape) (square-length shape))] 
     [(circle? shape) (* 3.14 (* (circle-radius shape) (circle-radius shape)))] 
     [(rectangle? shape) (* (rectangle-width shape) (rectangle-height shape))] 
     [else (error 'area-of-shape "Unhandled Shape Condition.")]) 
    (error 'area-of-shape "Argument not a Shape."))) 

;; Example uses 
(area-of-shape (square 0 10)) 
(area-of-shape (circle 0 10)) 
(area-of-shape (rectangle 0 10 10)) 

Кстати, что-то вроде area-of-shape, я считаю, что удобней использовать match чем cond:

(define (area-of-shape shape) 
    (match shape 
    [(square _ len) (* len len)] 
    [(circle _ rad) (* 3.14 (* rad rad))] 
    [(rectangle _ w h) (* w h)])) 

Answer 2

Я хотел бы сделать это следующим образом:

(define (area-of-shape shapeA) 
    (cond 
    [(square? shapeA) (* (square-lenght shapeA) (square-lenght shapeA))] 
    [(circle? shapeA) (* 3.14 (* (circle-radius shapeA) (circle-radius shapeA)))] 
    [(rectangle? shapeA) (* (rectangle-width shapeA) (rectangle-height shapeA))] 
    [else (error 'area-of-shape "A shape is either a square, a circle, or, a rectangle")]))