Элементы массива проверить as3

Question

У меня есть 4 MovieClips в массиве

var tiles:Array = new Array("tile1","tile2","tile3","tile4"); 

Внутри каждого из них есть код пропадать, когда он щелкнул мышью на втором кадре.

this.visible = false; 

С основной временной шкалы находится элемент управления щелчком мыши для каждой из плиток (отображается только первый).

tile1.addEventListener(MouseEvent.CLICK, fl_); 

function fl_(event:MouseEvent):void 
{ 
    tile1.gotoAndStop(2); 
} 

Как я могу сделать это так, когда все плитки в массиве становятся невидимыми, вспышка, чтобы принять меры (например, чтобы перейти к кадру 5)?

Спасибо!

Answer 1

Я посмотрел на ваш .fla. Вот два способа сделать то, что вы хотели:

на главной временной шкале: (заменить текущий основной график кадра 1 код со следующим)

stop(); 

//loop through every child of the `cont` container, and add the same click listener 
var i:int = cont.numChildren 
while(i--){ 
    var tile:MovieClip = cont.getChildAt(i) as MovieClip; 
    if(tile){ 
     tile.addEventListener(MouseEvent.CLICK, tileClick, false,0,true); 
    } 
} 

function tileClick(e:MouseEvent):void { 
    //this gets a reference to one that was clicked 
    var tile:MovieClip = e.currentTarget as MovieClip; 

    tile.gotoAndStop(2); 

    //loop through the tile array to see if any are still visible 
    var i:int = cont.numChildren 
    while(i--){ 
     tile = cont.getChildAt(i) as MovieClip; 
     if(tile && tile.currentFrame == 1) return; 
    } 

    //if we got this far, all the tiles are hidden, lets go to frame 5. 
    gotoAndStop(5); 
} 

---

Если выше пугающим и вы предпочли бы сохранить его, как это было раньше, то это все, что вы должны сделать: (опять же, этот код будет заменить текущий основной график кадр 1 код)

stop(); 

cont.tile1.addEventListener(MouseEvent.CLICK, tileClick); 
cont.tile2.addEventListener(MouseEvent.CLICK, tileClick); 
cont.tile3.addEventListener(MouseEvent.CLICK, tileClick); 
cont.tile4.addEventListener(MouseEvent.CLICK, tileClick); 

function tileClick(e:MouseEvent):void { 
    MovieClip(e.currentTarget).gotoAndStop(2); 
    if(cont.tile1.currentFrame == 1) return; 
    if(cont.tile2.currentFrame == 1) return; 
    if(cont.tile3.currentFrame == 1) return; 
    if(cont.tile4.currentFrame == 1) return; 

    //if we got this far, all the tiles are hidden, lets go to frame 5. 
    gotoAndStop(5); 
}