Слияние почты в PDF, а не Печать

Question

Я использовал учебник со страницы электронных таблиц. Советы по Excel: слияние писем - без Word для создания отчета о стиле слияния для 100 записей. Использование индекса записи и косвенных поисков из другого листа все отлично работает, чтобы генерировать нужные мне отчеты.

Вместо того, чтобы печатать, я хочу сохранить каждый вывод в формате PDF с именем, использующим поле в слиянии. Я попытался заменить «ActiveSheet.PrintOut» на «ActiveSheet.ExportasFixedFormat» и ввел спецификации PDF. Это работало в определенной степени тем, что мне удалось создать PDF-файл в указанном месте, но он будет генерировать только один PDF-файл, а не весь диапазон, который я пытался создать.

Вот код, который я пытаюсь использовать. Я просмотрел другие ответы о том, как перебирать каждую запись для создания отдельных PDF-файлов, но не смог генерировать больше, чем один PDF-файл за раз.

Public Const APPNAME As String = "Progress Report" 

Option Explicit 

Sub PrintForms() 
    Dim StartRow As Integer 
    Dim EndRow As Integer 
    Dim Msg As String 
    Dim HRETID As String 
    Dim i As Integer 

Sheets("ProgressReport").Activate 
StartRow = Range("StartRow") 
EndRow = Range("EndRow") 
HRETID = Range("HRETID") 

If StartRow > EndRow Then 
    Msg = "ERROR" & vbCrLf & "The starting row must be less than the ending row!" 
    MsgBox Msg, vbCritical, APPNAME 
End If 

For i = StartRow To EndRow 
    Range("RowIndex") = i 
     ActiveSheet.ExportAsFixedFormat _ 
     Type:=xlTypePDF, _ 
     Filename:="C:\Users\ewilliamson\PDFs\" & HRETID, _ 
     Quality:=xlQualityStandard, _ 
     IncludeDocProperties:=True, _ 
     IgnorePrintAreas:=False 
Next i 
End Sub 

Answer 1

Если вы хотите, чтобы ваше имя файла, чтобы быть динамическим, то вам необходимо подобрать значение из HRETID внутри цикла, а не только один раз вне цикла:

For i = StartRow To EndRow 
    Range("RowIndex") = i 
     ActiveSheet.ExportAsFixedFormat _ 
     Type:=xlTypePDF, _ 
     Filename:="C:\Users\ewilliamson\PDFs\" & _ 
        Range("HRETID").Value & ".pdf", _ 
     Quality:=xlQualityStandard, _ 
     IncludeDocProperties:=True, _ 
     IgnorePrintAreas:=False 
Next i 

Answer 2

Похоже, что значение HRETID в вашем имени файла: = присваивание не меняется. (Для этого ему нужно будет присвоить новое значение для каждой строки в вашем цикле)

Если вы хотите перебрать столбец, чтобы назначить значение ячеек в этом столбце для HRETID, попробуйте это:

Dim rItem as Range 

for each ritem in Range("HRETID") 
    ActiveSheet.ExportAsFixedFormat _ 
    Type:=xlTypePDF, _ 
    Filename:="C:\Users\ewilliamson\PDFs\" & ritem.value , _ 
    Quality:=xlQualityStandard, _ 
    IncludeDocProperties:=True, _ 
    IgnorePrintAreas:=False 

next rItem 

Обратите внимание, что вам не нужно HRETID в качестве строки, потому что вы можете получить значение ячеек из rItem.