«Ожидаемый тип аннулируются» - функция VHDL ошибка

Question

Я написал простую функцию, которая делает log2 вычисление любого целого числа, а затем «ceils» это до следующего целого числа:

function log2ceil(intVal: integer) return natural is 
    variable i  : natural; 
    variable bitCount : natural; 
begin 

    i := (intVal - 1); 
    bitCount := 0; 

    while (i > 0) loop 
     bitCount := bitCount + 1; 
     i:=shiftRightInt(i,1); 
    end loop; 

    return bitCount; 
end log2ceil; 

---

function shiftRightInt(ValueToShift: integer; NrToShift:natural) return integer is 
begin 
    return to_integer(shift_right(to_unsigned(ValueToShift, 32), NrToShift)); 
end shiftRightInt; 

Работает, отлично. Проблема заключается в симуляции. Каждый раз, когда я пытаюсь имитировать его с помощью простого вызова функции в испытательном стенде:

stim: process 
begin 
    wait for 10 ns; 
    log2ceil(3); 
    wait; 
end process; 

это дает мне следующую ошибку:

ERROR: [VRFC 10-1472] type error near log2ceil ; expected type void 

Почему ожидать типа Пустоты? И как я могу избежать получения этой ошибки?

Answer 1

Код:

stim: process 
begin 
    wait for 10 ns; 
    log2ceil(3); 
    wait; 
end process; 

описывает вызов процедуры, но log2ceil функция. Процедуры имеют возвращаемый тип void, тогда как ваша функция возвращает целое число.

Вы должны обеспечить фиктивную переменную для сбора возвращаемого значения:

stim: process 
    variable dummy : natural; 
begin 
    wait for 10 ns; 
    dummy := log2ceil(3); 
    wait; 
end process; 

Сообщение об ошибке немного загадочным, но верно!

Answer 2

Ваш инструмент не дает очень полезного сообщения об ошибке. Проблема в том, что вы ссылаетесь на функцию в log2ceil, которая еще не объявлена. Учитывая порядок, который вы определяете, shiftRightInt пока не отображается.

Когда я скомпилировать код с Modelsim, я получаю: `

(vcom-1136) Unknown identifier "shiftRightInt".

Edit: После включения вашего процесса я получил ошибку @ user1155120 указал. В Modelsim:

No feasible entries for subprogram "log2ceil".

Как указано user1155120, вы вызываете функцию в контексте процедуры. Вам нужно присвоить возвращаемое значение чему-то.

Во-первых, вы можете поменять порядок деклараций. Т.е .:

function shiftRightInt(ValueToShift: integer; NrToShift:natural) return integer is 
begin 
    return to_integer(shift_right(to_unsigned(ValueToShift, 32), NrToShift)); 
end shiftRightInt; 

function log2ceil(intVal: integer) return natural is 
    variable i  : natural; 
    variable bitCount : natural; 
begin 

    i := (intVal - 1); 
    bitCount := 0; 

    while (i > 0) loop 
     bitCount := bitCount + 1; 
     i:=shiftRightInt(i,1); 
    end loop; 

    return bitCount; 
end log2ceil; 

Другой определить "прототипом" shiftRightInt:

function shiftRightInt(ValueToShift: integer; NrToShift:natural) return integer; 

function log2ceil(intVal: integer) return natural is 
    variable i  : natural; 
    variable bitCount : natural; 
begin 

    i := (intVal - 1); 
    bitCount := 0; 

    while (i > 0) loop 
     bitCount := bitCount + 1; 
     i:=shiftRightInt(i,1); 
    end loop; 

    return bitCount; 
end log2ceil; 

function shiftRightInt(ValueToShift: integer; NrToShift:natural) return integer is 
begin 
    return to_integer(shift_right(to_unsigned(ValueToShift, 32), NrToShift)); 
end shiftRightInt;