Путаница с умозаключения типа Haskell

Question

Я не понимаю, почему следующая функция работает:

isLongerThanN :: Integral n => n -> [a] -> Bool 
isLongerThanN n xs = length xs > fromIntegral n 

но следующий не будет:

isLongerThanN' :: Integral n => n -> [a] -> Bool 
isLongerThanN' n xs = length xs > n 

, который бросает ошибку

Could not deduce (n ~ Int) 
    from the context (Integral n) 
     bound by the type signature for 
       isLongerThanN' :: Integral n => n -> [a] -> Bool 
     at blah.hs:140:1-35 
     `n' is a rigid type variable bound by 
      the type signature for 
      isLongerThanN' :: Integral n => n -> [a] -> Bool 
      at blah.hs:140:1 
    In the second argument of `(>)', namely `n' 
    In the expression: length xs > n 
    In an equation for `isLongerThanN'': 
     isLongerThanN' n xs = length xs > n 

(что я, вероятно, неправильно понял)

Во всяком случае, я ожидаю, что это будет наоборот, поскольку fromIntegral эффективно расширяет тип переменной n.

Answer 1

Рассмотрим выражение, которое не работает

isLongerThanN' :: Integral n => n -> [a] -> Bool 
isLongerThanN' n xs = length xs > n 

n может быть любым целым числом, у типа, поэтому он может быть передан в Integer или Word или Int. (>) имеет тип Ord a => a -> a -> Bool, поэтому оба его левого и правого операнда должны быть одного типа. length xs возвращает Int, поэтому этот тип должен быть таким. Но, n может быть любым Integral, не обязательно Int, поэтому нам нужно каким-то образом разрешить n преобразовать в Int. Это то, что делает fromIntegral (факт, что он также позволяет n быть любым Num в основном не имеет значения).

Мы могли бы расширить рабочую версию, чтобы выглядеть следующим образом:

toInt :: Integral n => n -> Int 
toInt = fromIntegral 

isLongerThanN :: Integral n => n -> [a] -> Bool 
isLongerThanN n xs = length xs > toInt n 

, что делает его более ясным, что мы используем специализированную версию fromIntegral.

(Обратите внимание, что isLongerThanN n xs = fromIntegral (length xs) > n также работает, потому что это позволяет результат length в соответствии с типом n.)