Если запрос Else пуст

Question

Я использую CFLDAP для аутентификации пользователей с использованием активного каталога. Я пытаюсь написать оператор if в случае, если информация пользователя не возвращается как заверенная. Я думал, что могу проверить, используя <cfif AuthenticateUser.RecordCount gt 0>, который работает до тех пор, пока информация верна, но если введена неправильная информация и ничего не аутентифицировано, она не запускает инструкцию else. Любая помощь с этим будет принята с благодарностью!

<cfldap action="query" 
       name="AuthenticateUser" 
       attributes="dn,mail,givenname,sn,samaccountname,memberof" 
       start="DC=domain,DC=net" 
       filter="(&(objectclass=user)(samAccountName=#trim(form.user_name)#))" 
       server="servername" 
       Port="389" 
       username="tc\#trim(form.user_name)#" 
       password="#trim(form.user_pass)#"> 
<cfoutput>#AuthenticateUser.RecordCount#</cfoutput> 
<!--- Get all records from the database that match this users credentials ---> 
<cfquery name="userVerify" datasource="test"> 
    SELECT * 
    FROM dbo.Users 
    WHERE user_name = <cfqueryparam value="#AuthenticateUser.samaccountname#" cfsqltype="cf_sql_varchar" /> 
</cfquery> 
<cfif AuthenticateUser.RecordCount gt 0> 
    <!--- This user has logged in correctly, change the value of the session.allowin value ---> 
    <cfset session.allowin = "True" /> 
    <cfset session.employee_number = userVerify.employee_number /> 

    <!--- Now welcome user and redirect to "index.html" ---> 
    <script> 
     self.location="../dashboard/dashboard.cfm"; 
    </script> 
<cfelse> 
    <!--- this user did not log in correctly, alert and redirect to the login page ---> 
    <script> 
     alert("Your credentials could not be verified, please try again!"); 
     self.location="Javascript:history.go(-1)"; 
    </script> 
    </cfif> 

Я также попытался: <cfif len(AuthenticateUser)>

Answer 1

Я думаю, что это порождает ошибку при сбое запроса. Попробуйте это:

<cftry> 
    <cfldap action="query" 
       name="AuthenticateUser" 
       attributes="dn,mail,givenname,sn,samaccountname,memberof" 
       start="DC=domain,DC=net" 
       filter="(&(objectclass=user)(samAccountName=#trim(form.user_name)#))" 
       server="servername" 
       Port="389" 
       username="tc\#trim(form.user_name)#" 
       password="#trim(form.user_pass)#"> 
    <cfset LoginStatus = "Success"> 
    <cfcatch type="any"> 
     <cfset LoginStatus = "Failed"> 
    </cfcatch> 
</cftry> 

Тогда ваш Cfif будет что-то вроде этого:

<cfif LoginStatus eq "Success"> 
    <!--- This user has logged in correctly, change the value of the session.allowin value ---> 
    <cfset session.allowin = "True" /> 
    <cfset session.employee_number = userVerify.employee_number /> 

    <!--- Now welcome user and redirect to "index.html" ---> 
    <script> 
     self.location="../dashboard/dashboard.cfm"; 
    </script> 
<cfelse> 
    <!--- this user did not log in correctly, alert and redirect to the login page ---> 
    <script> 
     alert("Your credentials could not be verified, please try again!"); 
     self.location="Javascript:history.go(-1)"; 
    </script> 
</cfif> 

Я думаю, что это работает на CF9.

Answer 2

Это отформатированные комментарий. Вы пытаетесь сделать слишком много сразу. Пойдите шаг за шагом. Начать с этого:

<cfdump var="before cfldap tag<br />"> 

<cfldap action="query" 
      name="AuthenticateUser" 
etc 
> 
<cfdump var="after cfldap tag<br />"> 
<cfdump var = "#AuthenticateUser#"> 
<cfdump var="after cfdump<br />"> 

Запустите этот код с действительными и недопустимыми учетными данными. Посмотрите, что вы получаете. Реагировать соответственно.

Answer 3

Вот как я это делаю. Я пытаюсь запустить запрос в отношении нашего домена, используя предоставленное имя пользователя и пароль. Если введенное имя пользователя и пароль недопустимы, генерируется ошибка.

<cftry> 
    <cfldap action="Query" 
     name="ADResult" 
     attributes="dn" 
     start="DC=domain,DC=net" 
     filter="sAMAccountName=administrator" 
     server="servername" 
     scope = "subtree" 
     username="#arguments.username#" 
     password="#arguments.password#" /> 

    <cfset isAuthenticated = true /> 
<cfcatch type="any"> 
    <cfset isAuthenticated = false /> 
</cfcatch> 
</cftry> 

<cfreturn isAuthenticated /> 

Я завершаю это функцией под названием «аутентифицировать» и выставляю ее через веб-службу, которую я вызываю из своих приложений. Если мне тогда понадобятся дополнительные сведения о пользователе (mail, givenName и т. Д.), У меня есть еще одна функция в той же веб-службе, которую я буду вызывать после того, как я уверен, что пользователь аутентифицирован. Обратите внимание, что в этой другой функции я использую имя пользователя и пароль администратора для выполнения запроса.

<cfldap action="Query" 
    name="ADResult" 
    attributes="mail,givenName" 
    start="DC=domain,DC=net" 
    filter="sAMAccountName=#arguments.username#" 
    server="servername" 
    scope = "subtree" 
    username="administrator" 
    password="myAdminPassword" /> 

Я беру результаты этого, заполняя объект запроса или структуру и возвращаю его вызывающей функции.

Так что весь процесс своего рода выглядит следующим образом:

<cfset objAD = createobject("webservice", "http://mywebservice.com") /> 
<cfset isAuthenticated = objAD.authenticate(form.username, form.password) /> 
<cfif isAuthenticated> 
    <cfset userDetails = objAD.getUserDetails(form.username)> 
</cfif> 

Надеется, что это помогает.