XSL/HTML-код корректировки строки таблицы

-1

В настоящее время я использую XML v1.0. Я сталкиваюсь с проблемой, когда я не могу создать новую строку для каждой из моих «Собаков». Я приложил скриншот, чтобы визуализировать то, что у меня есть, и результат. Первый скриншот - это то, что у меня есть. Второй скриншот указывает на то, что я пытаюсь исправить. Каждая из «Собаки» должна быть в собственной коробке.XSL/HTML-код корректировки строки таблицы

enter image description here

То, что я пытаюсь сделать, это длинный список «собачкой», чтобы быть в его собственном табличном пространстве. Текущий код у меня есть что-то вроде этого:

 <xsl:for-each select="animal-list/list"> 
      <tr> 
       <td> 
        <xsl:apply-templates select="cat-list"/> 
       </td> 
       <td> 
        <xsl:for-each select="dog-list"> 
         <apply-templates select="dog"> 
         <xsl:if test="position() != last()"> 
          <br/> 
         </xsl:if> 
        </xsl:for-each> 
       </td> 
      </tr> 
     </xsl:for-each>

Я попытался заменить <br/> с различными различными метками, чтобы попытаться достичь своей цели. Но я ничего не пробовал. Таким образом, чтобы прояснить мой вопрос, как я могу иметь «собака» в их собственных данных/строки Столик, как и в том, чтобы линии между каждым «собачкой»

Edit:

Вот данные XML:

   <animal-list> 
        <list> 
         <cat-list>Cat</cat-list> 
         <dog-list>Dog</dog-list> 
        </list> 
        <list> 
         <cat-list>Cat</cat-list> 
         <dog-list>Dog</dog-list> 
        </list> 
        <list> 
         <cat-list>Cat</cat-list> 
         <dog-list>Dog</dog-list> 
        </list> 
        <list> 
         <cat-list>Cat</cat-list> 
         <dog-list>Dog</dog-list> 
        </list> 
        <list> 
         <cat-list>Cat</cat-list> 
         <dog-list>Dog</dog-list> 
        </list> 
        <list> 
         <cat-list>Cat</cat-list> 
         <dog-list>Dog</dog-list> 
        </list> 
        <list> 
         <cat-list>Cat</cat-list> 
         <dog-list>Dog</dog-list> 
        </list> 
        <list> 
         <cat-list>Cat</cat-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
         <dog-list>Dog</dog-list> 
        </list> 
       </animal-list>

источник

2013-12-13 misterbear

Вы должны показать свой входной XML и указать, какие собаки должны быть связаны с какими кошками. – kjhughes

Для этого я не слишком беспокоюсь о том, что такое данные. Я просто застрял в основном на том, что сделало бы таблицу действительно отображаемой правильно, независимо от того, что говорят данные, собаки, кошки, обезьяны и т. Д. Я говорю: '' или '' не работает, если заменив его на «
», какой другой метод мог бы достичь результата. – misterbear

Вы можете не беспокоиться, но вопрос не совсем ясен без него. Также трудно проверить ответ без каких-либо данных - так почему бы вам просто не предоставить его вместо того, чтобы ожидать, что другие сделают это за вас? –

Это какой-то странный вход, я скажу. Во всяком случае, вот один из способов взглянуть на это. Это предполагает, что столбцы кошки и собаки независимы друг от друга.

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/> 

<xsl:template match="/"> 
<html> 
<body> 
<table> 
    <tr> 
     <th>Cats</th> 
     <th>Dogs</th> 
    </tr> 

    <xsl:call-template name="createRows"> 
     <xsl:with-param name="cats" select="animal-list/list/cat-list"/> 
     <xsl:with-param name="dogs" select="animal-list/list/dog-list"/> 
    </xsl:call-template> 

</table> 
</body> 
</html> 
</xsl:template> 

<xsl:template name="createRows"> 
    <xsl:param name="cats"/> 
    <xsl:param name="dogs"/> 
    <xsl:param name="i" select="1"/> 

    <xsl:if test="$i &lt;= count($cats) or $i &lt;= count($dogs)"> 
     <tr> 
      <td><xsl:value-of select="$cats[$i]"/></td> 
      <td><xsl:value-of select="$dogs[$i]"/></td> 
     </tr> 
     <xsl:call-template name="createRows"> 
      <xsl:with-param name="cats" select="$cats"/> 
      <xsl:with-param name="dogs" select="$dogs"/> 
      <xsl:with-param name="i" select="$i+1"/> 
     </xsl:call-template> 
    </xsl:if> 

</xsl:template> 

</xsl:stylesheet>

В случае выше предположение неверно:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/> 

<xsl:template match="/"> 
<html> 
<body> 
<table> 
    <tr> 
     <th>Cats</th> 
     <th>Dogs</th> 
    </tr> 
    <xsl:for-each select="animal-list/list"> 
     <tr> 
      <td> 
       <xsl:if test="count(dog-list) > 1"> 
        <xsl:attribute name="rowspan"> 
         <xsl:value-of select="count(dog-list)"/> 
        </xsl:attribute> 
       </xsl:if> 
       <xsl:value-of select="cat-list"/> 
      </td> 
      <td><xsl:value-of select="dog-list[1]"/></td> 
     </tr>   
     <xsl:for-each select="dog-list[position() > 1]"> 
      <tr><td><xsl:value-of select="."/></td></tr> 
     </xsl:for-each> 
    </xsl:for-each> 
</table> 
</body> 
</html> 
</xsl:template> 
</xsl:stylesheet>

источник

2013-12-13 09:00:37

В этом случае tr-tr (с позицией> 1) будет находиться внутри первого tr. Вы должны выставить их на улицу. – Fernando

@ Fernando Спасибо, я уже исправил это (я думаю). –

Да, вот что я имел в виду :) – Fernando

Никакой XML не означает XSLT, поэтому, я думаю, у вас проблема с HTML больше, чем с XSLT. Вы должны использовать rowspan атрибут, например:

<table border="1"> 
    <tr> 
    <td rowspan="5">cat</td> 
    <td>dog</td> 
    </tr> 
    <tr> 
    <td>dog</td> 
    </tr> 
    <tr> 
    <td>dog</td> 
    </tr> 
    <tr> 
    <td>dog</td> 
    </tr> 
    <tr> 
    <td>dog</td> 
    </tr> 
</table>

Как сделать это с помощью XSLT это еще один вопрос, который не может быть решен без XML.

Обновлено: Вы можете попробовать с этим XSL:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl"> 
    <xsl:output omit-xml-declaration="yes" method="xml" indent="yes" /> 

<!-- template for root element: table element and apply-templates for cat-list elements --> 
<xsl:template match="/"> 
    <table border="1"> 
    <xsl:apply-templates select="animal-list/list/cat-list"/> 
    </table> 
</xsl:template> 

<!-- template for cat-list elements --> 
<xsl:template match="cat-list"> 
    <!-- count all dog-list elements which are 'children of my parent node' --> 
    <xsl:variable name="mysiblings" select="parent::list/dog-list" /><!-- this variable will contain all of mi dog-list siblings --> 
    <xsl:variable name="myspan" select="count($mysiblings)" /><!-- this variable will contain the number of them --> 

    <!-- for every cat-list: one row --> 
    <tr> 
    <td rowspan="{$myspan}"> 
     <xsl:value-of select="." /><!-- output my text --> 
    </td> 
    <!-- first dog-list: inside same tr --> 
    <xsl:apply-templates select="$mysiblings[1]" /> 
    </tr> 
    <!-- rest of them outside: they have their own tr: --> 
    <xsl:apply-templates select="$mysiblings[position() &gt; 1]" /> 
</xsl:template> 

<!-- template for dog-list elements, general --> 
<xsl:template match="dog-list"> 
    <!-- tr and td --> 
    <tr> 
    <td> 
     <xsl:value-of select="." /><!-- output my text --> 
    </td> 
    </tr> 
</xsl:template> 

<!-- template for the first one. This one will go inside same tr as the cat --> 
<xsl:template match="dog-list[position() = 1]"> 
    <!-- just td --> 
    <td> 
    <xsl:value-of select="." /><!-- output my text --> 
    </td> 
</xsl:template> 

</xsl:stylesheet>

Надеется, что это помогает.

источник

2013-12-13 07:08:05 Fernando

Не знал, что данные XML на самом деле важны. Поэтому я создал что-то похожее на то, что у меня есть xml-данные, поскольку я фактически не могу поделиться фактическим контентом. Надеюсь, это создает меньше путаницы. Спасибо за помощь. XML добавлен в исходное сообщение. – misterbear

XSL/HTML-код корректировки строки таблицы

ответ

Смежные вопросы