Повторная запись инструкции AVERAGEIFS в инструкцию STDEV

Question

Я ищу, чтобы переписать инструкцию averageifs в инструкцию STDEV. В настоящее время у меня есть средний оператор if, который ищет текущее имя «N» в типе «M» и находит тот же тип и имя в столбцах «A» и «B» и будет усреднять результаты «C» для тех строк.

=AVERAGEIFS(C:C,A:A,M4,B:B,N4) 
=AVERAGEIFS(C:C,A:A,M5,B:B,N5) 
=AVERAGEIFS(C:C,A:A,M6,B:B,N6) 
etc... 

Я хотел бы сделать то же самое с СТАНДОТКЛОН, однако требования входов различны, как STDEVIFS, не существует.

=STDEV(BG:BG,C:C,BL4,K:K,BM4) предоставит разработчику всех столбцов. Как я могу исправить это так же, как и оператор averageifs, но для STDEV.

A  B   C      M  N   O 
    x  x   x      x  x   x 
    x  x   x      x  x   x 
Type Name  Mass     Type  Name  AVG Mass 
Fruit Apple  3     Fruit Apple  4.25 
Veggie Tomato  5     Fruit Orange  6.5 
Veggie Lettuce  1     Veggie Tomato  6.333 
Veggie Tomato  7     Veggie Lettuce  2.3333 
Fruit Orange  6     Fruit Watermelon 5.5 
Fruit Apple  5     Veggie Watermelon 4 
Fruit Watermelon 5 
Veggie Watermelon 3 
Fruit Apple  3 
Fruit Apple  6 
Veggie Watermelon 5 
Fruit Watermelon 6 
Fruit Orange  7 
Veggie Lettuce  3 
Veggie Lettuce  3 
Veggie Tomato  7 

x = non included info 

Answer 1

Вы бы нам форма массива СТАНДОТКЛОНА с IF() внутри:

=STDEV(IF(($A$4:$A$19=M4)*($B$4:$B$19=N4),$C$4:$C$19)) 

Будучи формулой массива оно должно быть подтверждено с помощью Ctrl-Shift-Enter вместо ввода при выходе режим редактирования. Если все сделано правильно, Excel поместит {} вокруг формулы.

Формулы массива отличаются от обычной формулы тем, что они будут вычислять каждую вещь в ссылочном диапазоне, и поэтому не следует использовать полные ссылки столбцов.

Вы можете сделать, как сказал Рон в своем ответе, и назовите диапазоны, чтобы ограничить ссылки. Или вы можете использовать таблицу, которая будет делать то же самое или просто ограничить диапазон, как я сделал здесь.

Answer 2

Вы можете использовать IF функцию, чтобы возвращать либо соответствующее значение, или логическое значение FALSE, которое будет проигнорировано. Таким образом, учитывая вашу выборку данных, и пример может быть: (введен с Ctrl + сдвигом + введите как формулу массива)

=STDEV(IF((Type=M5)*(Name=N5),Mass)) 

• Тип является именованным диапазоном в колонке A
• Имя является именованный диапазон в колонке B
• Масса именованный диапазон в колонке C
• M5 содержит тип, который вы ищете
• N5 содержит имя, которое вы ищете

Примечание: Вы можете использовать весь (или частично) аргументы столбцов вместо именованных диапазонов в приведенных выше формулах - это только будет менее эффективным.