Укажите диапазон ячеек для .validation

Question

Я хотел бы вставить список проверки данных, который захватывает данные с другого листа. столбец, из которого будет создан список, хранится в другой переменной, которая является динамической. Мой код до сих пор:

pRange = Sheets("Payer Output").Cells(24, 3).Value 

With Sheets("Payer Output").Range("C23").Validation 
.Delete 
.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _ 
Operator:=xlBetween, Formula1:=Sheets("Payers in Top 4").Cells(3, pRange) 
.InCellDropdown = True 
.InputTitle = "" 
.ErrorTitle = "" 
.InputMessage = "" 
.ErrorMessage = "" 
.ShowInput = True 
.ShowError = True 
End With 

Эта формула создает список, и выглядит в правильной колонке, однако текущий код указывает только список должен выглядеть в одной ячейке, поэтому, когда список формируется, есть только одно значение. Как указать диапазон ячеек для строки 'formula1: ='? Я пробовал:

Formula1:=Sheets("Payers in Top 4").Range(Cells(3, pRange), Cells(10,pRange)) 

Но это не работает. Спасибо за помощь!

Answer 1

Иногда я просто назвать диапазон и поставить именованный диапазон в списке.

Sub AddDtaVal() 
     pRange = Sheets("Payer Output").Range("C24").Value 

    Sheets("Payers in Top 4").Range(Sheets("Payers in Top 4").Cells(3, pRange), Sheets("Payers in Top 4").Cells(10, pRange)).Name = "List" 

    With Sheets("Payer Output").Range("C23").Validation 
     .Delete 
     .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _ 
      xlBetween, Formula1:="=List" 
     .IgnoreBlank = True 
     .InCellDropdown = True 
     .InputTitle = "" 
     .ErrorTitle = "" 
     .InputMessage = "" 
     .ErrorMessage = "" 
     .ShowInput = True 
     .ShowError = True 
    End With 
End Sub 

Answer 2

Вам необходимо создать адресную формулу в строке, Excel-стиль: 'Sheet Name'!A1:A10

Dim StrFormula As String 
Dim pRange As Long 

pRange = Sheets("Payer Output").Cells(24, 3).Value 
With Sheets("Payers in Top 4") 
    StrFormula = "'" & .Name & "'!" & .Range(.Cells(3, pRange), .Cells(10, pRange)).Address 
End With 

With Sheets("Payer Output").Range("C23").Validation 
    .Delete 
    .Add Type:=xlValidateList, _ 
      AlertStyle:=xlValidAlertStop, _ 
      Operator:=xlBetween, _ 
      Formula1:=StrFormula 
    .InCellDropdown = True 
    .InputTitle = "" 
    .ErrorTitle = "" 
    .InputMessage = "" 
    .ErrorMessage = "" 
    .ShowInput = True 
    .ShowError = True 
End With 

Answer 3

Попробуйте

.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _ 
     Operator:=xlBetween, Formula1:="='Payers in Top 4'!" & Worksheets("Payers in Top 4").Cells(3, pRange).Resize(8).Address