VBA Excel: присвоение значений диапазона новому диапазону

Question

У меня возникли проблемы с назначением значений из одного диапазона рабочей книги в диапазон в моей текущей книге. Когда я назначаю свой диапазон с помощью Range («A1: C1»), этот код работает нормально, однако, когда мой диапазон определен с использованием Range (Cells (1,1), Cells (1,3)), функция не работает:

Sub CopyRange() 
    Dim inputExcel As Excel.Application, BookA As Workbook 
    Path_A = ThisWorkbook.Path & "\Book_A.xlsx" 
    Set inputExcel = New Excel.Application 
    Set BookA = inputExcel.Workbooks.Open(Path_A, ReadOnly:=True) 

    'THIS WORKS: 
    ThisWorkbook.Sheets(1).Range("A1:C1").Value = _ 
    BookA.Sheets(1).Range("A1:C1").Value 

    'THIS DOESN'T WORK: 
    ThisWorkbook.Sheets(1).Range(Cells(1, 1), Cells(1, 3)).Value = _ 
    BookA.Sheets(1).Range(Cells(1, 1), Cells(1, 3)).Value 
End Sub 

Я знаю, что это должна быть простая проблема синтаксиса, но я не смог понять это. Как я могу получить задания Range с использованием «Ячейки»?

Answer 1

ты должен квалифицировать Cells вызовы с объектом рабочего листа тоже:

ThisWorkbook.Sheets(1).Range(ThisWorkbook.Sheets(1).Cells(1, 1), ThisWorkbook.Sheets(1).Cells(1, 3)).Value = _ 
    BookA.Sheets(1).Range(BookA.Sheets(1).Cells(1, 1), BookA.Sheets(1).Cells(1, 3)).Value 

для смежных диапазонов, как, что вы также можете использовать Изменить размер:

ThisWorkbook.Sheets(1).Cells(1, 1).Resize(, 3).Value = _ 
     BookA.Sheets(1).Cells(1, 1).Resize(, 3).Value 

Answer 2

Я думаю, что в конечном счете, вы собираетесь об это не лучший способ решить проблему. У вас есть object.object.object.object нотации в вашем коде, что громоздко и трудно интерпретировать и исправлять.

Если определить еще несколько переменных, то код будет проще, чтобы диагностировать и решить проблему:

Dim myAddr as String 'A string to represent the Address of the range 
myAddr = Cells(1,1).Address & ":" & Cells(1,3).Address 

ThisWorkbook.Sheets(1).Range(myAddr).Value = BookA.Sheets(1).Range(myAddr).Value