Получить содержимое папки sharepoint с помощью Excel VBA

Question

Обычно я использую этот фрагмент кода для извлечения содержимого папки в VBA. Но это не работает в случае sharepoint. Как я могу сделать ?

Dim folder As folder 
Dim f As File 
Dim fs As New FileSystemObject 

Set folder = fs.GetFolder("//sharepoint.address/path/to/folder") 

For Each f In folder.Files 
    'Do something 
Next f 

EDIT (после хорошего комментария по shahkalpesh):

я могу получить доступ к SharePoint, если я ввожу адрес в Windows Explorer. Доступ к sharepoint требует аутентификации, но он прозрачен, потому что он зависит от входа Windows.

Answer 1

Используйте путь UNC, а не HTTP. Этот код работает:

Public Sub ListFiles() 
    Dim folder As folder 
    Dim f As File 
    Dim fs As New FileSystemObject 
    Dim RowCtr As Integer 

    RowCtr = 1 
    Set folder = fs.GetFolder("\\SharePointServer\Path\MorePath\DocumentLibrary\Folder") 
    For Each f In folder.Files 
     Cells(RowCtr, 1).Value = f.Name 
     RowCtr = RowCtr + 1 
    Next f 
End Sub 

Чтобы получить путь UNC использовать, перейдите в папку в библиотеке документов, выпадающее меню Действия и выберите Открыть в проводнике Windows. Скопируйте путь, который вы видите там, и используйте это.

Answer 2

Попробуйте сопоставить библиотеку sharepoint с буквой диска в окнах. Затем выберите диск и путь в вашем коде.

Answer 3

ИМХО самый крутой путь - через WebDAV (без сетевой папки, поскольку это часто не допускается). Это можно сделать с помощью объектов ActiveX Data Objects, как это изложено в этой замечательной статье excellent article (код можно использовать непосредственно в Excel, недавно использовал концепцию).

Надеюсь, это поможет!

http://blog.itwarlocks.com/2009/04/28/accessing-webdav-in-microsoft-word-visual-basic/

оригинальная ссылка мертва, но, по крайней мере, текстовое содержимое по-прежнему доступен на archive.org: http://web.archive.org/web/20091008034423/http://blog.itwarlocks.com/2009/04/28/accessing-webdav-in-microsoft-word-visual-basic

Answer 4

Единственный способ я нашел, чтобы работать с файлами на SharePoint, имея для прав сервера - сопоставить папку WebDAV с буквой диска. Вот пример реализации.

Добавить ссылки на следующие библиотеки ActiveX в VBA:

• для Windows Script Host Object Model (wshom.ocx) - для WshNetwork
• Microsoft Scripting Runtime (scrrun.dll) - для FileSystemObject

Создать новый модуль класса, назовите его DriveMapper и добавьте следующий код:

Option Explicit 

Private oMappedDrive As Scripting.Drive 
Private oFSO As New Scripting.FileSystemObject 
Private oNetwork As New WshNetwork 

Private Sub Class_Terminate() 
    UnmapDrive 
End Sub 

Public Function MapDrive(NetworkPath As String) As Scripting.Folder 
    Dim DriveLetter As String, i As Integer 

    UnmapDrive 

    For i = Asc("Z") To Asc("A") Step -1 
    DriveLetter = Chr(i) 
    If Not oFSO.DriveExists(DriveLetter) Then 
     oNetwork.MapNetworkDrive DriveLetter & ":", NetworkPath 
     Set oMappedDrive = oFSO.GetDrive(DriveLetter) 
     Set MapDrive = oMappedDrive.RootFolder 
     Exit For 
    End If 
    Next i 
End Function 

Private Sub UnmapDrive() 
    If Not oMappedDrive Is Nothing Then 
    If oMappedDrive.IsReady Then 
     oNetwork.RemoveNetworkDrive oMappedDrive.DriveLetter & ":" 
    End If 
    Set oMappedDrive = Nothing 
    End If 
End Sub 

Затем вы можете реализовать его в вашем коде: отображение

Sub test() 
    Dim dm As New DriveMapper 
    Dim sharepointFolder As Scripting.Folder 

    Set sharepointFolder = dm.MapDrive("http://your/sharepoint/path") 

    Debug.Print sharepointFolder.Path 
End Sub 

Answer 5

Диска SharePoint (также HTTPS)

Получение содержимого SharePoint работал для меня с помощью подключенного диска переборе его в качестве объекта файловой системы ; Хитрость заключается в том, как настроить отображение: Затем скопировать путь (линия с HTTP *) (см ниже)

Используйте этот путь в карте диска из проводника или команды (т.е. net use N: https:://thepathyoujustcopied) Примечание : https работает нормально с windows7/8, а не с XP.

Это может сработать для вас, но я предпочитаю другой подход, поскольку буквы дисков различаются на каждом компьютере. Трюк здесь заключается в том, чтобы начать с sharepoint (а не из сценария VBA, обращающегося к sharepoint как веб-серверу).

Настройка подключения для передачи данных в Excel лист

• в SharePoint, перейдите к виду вы хотите контролировать
• вид экспорта в Excel (в 2010 году: библиотеки инструментов; libarry | экспорт в Excel)
• при просмотре этого первенствовать, вы найдете источник данных настройки (вкладка: данные, соединения, свойства, определение)

Вы можете включить этот запрос в vba или сохранить ссылку на базу данных в своем реестре, итерации по таблице с помощью VBA. Обратите внимание: на приведенном выше изображении не отображается фактическое соединение с базой данных (текст команды), в котором рассказывается, как получить доступ к sharepoint my.

Answer 6

Я потратил некоторое время на эту самую проблему - я пытался проверить файл, существовавший до его открытия.

В конце концов, я придумал решение с использованием XML и SOAP - используйте метод EnumerateFolder и вытащите ответ XML с содержимым папки.

Об этом сообщается в блоге here.

Answer 7

я возился с этой проблемой на некоторое время, и нашел очень простой, 2 строки решения, просто заменив «HTTP» и все слэши так:

myFilePath = replace(myFilePath, "/", "\") 
myFilePath = replace(myFilePath, "http:", "") 

Это может не сработать для всех, но он работал для меня

Если вы используете защищенный сайт (или хотите, чтобы удовлетворить обоих) вы можете добавить следующую строку:

myFilePath = replace(myFilePath, "https:", "") 

Answer 8

в дополнение к:

myFilePath = replace(myFilePath, "/", "\") 
myFilePath = replace(myFilePath, "http:", "") 

также заменить пространство:

myFilePath = replace(myFilePath, " ", "%20")